Непонятная ошибка при вызове функции

SKokorev

Я пытаюсь запустить инфопакет из макроса на VBA, но что-то не получается.

Код примерно такой:

Code:

   Dim oBAPICtrl As Object
    Dim oBAPILogon As Object
    Dim oBAPIPackage As Object
    Dim Request As Variant
    Dim Tabl As Object
    
    Set oBAPICtrl = CreateObject("SAP.BAPI.1")
    Set oBAPILogon = CreateObject("SAP.Logoncontrol.1")
    
    Set oBAPICtrl.Connection = oBAPILogon.NewConnection
    
    With oBAPICtrl.Connection
        .System = "система"
        .MessageServer = "сервер"
        .GroupName = "группа"
        .Client = "клиент"
        .User = "юзер"
        .Password = "пароль"
        .Language = "язык"
    End With
    
    If oBAPICtrl.Connection.Logon(1, False) = False Then
        MsgBox "Что-то не так..."
        End
    End If

    Set oBAPIPackage = oBAPICtrl.GetSAPObject("InfoPackage")
    
    
    oBAPIPackage.Schedule JobName:="Тех. имя инфопакета", _
                            RequestID:=Request, _
                            Return:=Tabl
        
    oBAPICtrl.Connection.Logoff

При этом все отрабатывает нормально вплоть до строки

Code:

oBAPIPackage.Schedule JobName:="Тех. имя инфопакета", _
                            RequestID:=Request, _
                            Return:=Tabl

на ней макрос валится с ошибкой
The persistent key for an business object instance of type InfoPackage has not been set.
Cannot invoke method SCHEDULE.

Смотрел исходники метода. Там в параметрах ввода вовсе не только название задания (job), а еще имя инфорпакета (infopackage) присутствует. Пробовал прописывать в jobname и то и другое с неизменно превосходным результатом - вышеупомянутой ошибкой.

Не сталкивался ли кто с похожей проблемой?

Заранее благодарен.

Bkmz

попробуй убить на машине касперского, если таковой имеется - он может душить макросы

G

А не проще ли через событие сделать?

Code:

   Set MyFunc = fns.Add("RSSM_EVENT_RAISE")
   MyFunc.exports("I_EVENTID") = EventName
   MyFunc.exports("I_EVENTPARM") = ""
   result = MyFunc.Call

а инфопакет уже пусть на это событие реагирует.

SKokorev

Спасибо, Bkmz, G.

Разобрался. Это правильно делается так:

Code:

Public Sub BAPI_Execute()


    Dim oBAPICtrl As Object
    Dim oBAPILogon As Object
    Dim oBAPIPackage As Object
    Dim Request As Variant
    Dim Tabl As Object
    
    Set oBAPICtrl = CreateObject("SAP.BAPI.1")
    Set oBAPILogon = CreateObject("SAP.Logoncontrol.1")
    
    Set oBAPICtrl.Connection = oBAPILogon.NewConnection
    
    With oBAPICtrl.Connection
        .System = "Система"
        .MessageServer = "Сервер"
        .GroupName = "Группа"
        .Client = "Номер клиента"
        .User = "Логин"
        .Password = "Пароль"
        .Language = "Язык"
    End With
    
    If oBAPICtrl.Connection.Logon(0, False) = False Then
        MsgBox "Что-то не так"
        End
    End If
    
    Set oBAPIPackage = oBAPICtrl.GetSAPObject("InfoPackage", "Тех. имя инфопакета")
    
    oBAPIPackage.Schedule RequestID:=Request, _
                          Return:=Tabl
        
    oBAPICtrl.Connection.Logoff
    
End Sub

Опять же, файл должен лежать на сервере приложений, ибо с локальной машины BW брать файл не хочет, но это уже частности. Я думаю, что если повозиться, то можно и для локали настроить, но мне это не нужно.

Еще раз спасибо.

G

А имя файла при планировке поменять можно?
Вообще, какие методы и поля есть у oBAPIPackage?

SKokorev

Я пока документации по методам и свойствам подключения не нашел, хотя кое-что про вызову BAPI можно найти по ключу "BAPI ActiveX" на help.sap.com.
А для самого объекта свойства и методы описаны в транзакции BAPI. Там же, кстати, есть описание различных объектов, необходимых для вызова функций.

vinter

чтото ничё подобного не нашёл для запуска цепочки

ZVladimir

vinter написал:

чтото ничё подобного не нашёл для запуска цепочки

Я тоже...

Непонятная ошибка при вызове функции

Кто сейчас на конференции