Abap в экспертной рутине

lescha

Добрый день.

Буду благодарен за любой совет.

мне нужно проверять 80 столбцов
Можно ли это сделать динамично?

Огромное спасибо

Code:

 LOOP AT SOURCE_PACKAGE ASSIGNING <source_fields>.
      IF <source_fields>-zzabrsn001 <> ''.
        RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
        RESULT_FIELDS-/bic/zrvk_abre = <source_fields>-zzabrsn001.
        APPEND RESULT_FIELDS TO RESULT_PACKAGE.
        CLEAR RESULT_FIELDS.
      ENDIF.
      IF <source_fields>-zzabrsn002 <> ''.
        RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
        RESULT_FIELDS-/bic/zrvk_abre = <source_fields>-zzabrsn002.
        APPEND RESULT_FIELDS TO RESULT_PACKAGE.
        CLEAR RESULT_FIELDS.
      ENDIF.
      IF <source_fields>-zzabrsn003 <> ''.
        RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
        RESULT_FIELDS-/bic/zrvk_abre = <source_fields>-zzabrsn003.
        APPEND RESULT_FIELDS TO RESULT_PACKAGE.
        CLEAR RESULT_FIELDS.
      ENDIF.
      IF <source_fields>-zzabrsn004 <> ''.
        RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
        RESULT_FIELDS-/bic/zrvk_abre = <source_fields>-zzabrsn004.
        APPEND RESULT_FIELDS TO RESULT_PACKAGE.
        CLEAR RESULT_FIELDS.
      ENDIF.
     ...
     ...
     IF <source_fields>-zzabrsn080 <> ''.
        RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
        RESULT_FIELDS-/bic/zrvk_abre = <source_fields>-zzabrsn080.
        APPEND RESULT_FIELDS TO RESULT_PACKAGE.
        CLEAR RESULT_FIELDS.
      ENDIF.
    ENDLOOP.

murmur

assign component of structure вам в руки. А тому, кто такое спроектировал, возможно, руки надо оторвать

lescha

спасибо.

но как это примерно должно выглядеть?

DO 80 TIMES.
я себе представлял это так:
IF <source_fields>-zzabrsn00.<SY-index> <> '' ???

ENDDO.

lescha

Мурмур, Огромное спасибо !!!

решение

Code:

    FIELD-SYMBOLS: <fs> TYPE any.
    BREAK-POINT.
    SORT SOURCE_PACKAGE BY objid ASCENDING.

    DATA: int TYPE i.

    LOOP AT SOURCE_PACKAGE ASSIGNING <source_fields>.
      int = 18. "начиная с 18 столбца через один находятся данные
      DO.
        IF int = 178. "DataSource состоит из 178 столбцов
          EXIT.
        ENDIF.
        ASSIGN COMPONENT int OF STRUCTURE <source_fields> TO <fs>.
        IF <fs> <> ''.
          RESULT_FIELDS-/bic/zrvk_mita = <source_fields>-objid.
          RESULT_FIELDS-datefrom  = <source_fields>-begda.
          RESULT_FIELDS-dateto  = <source_fields>-endda.
          RESULT_FIELDS-/bic/zrvk_itsn = <source_fields>-seqnr.
          RESULT_FIELDS-/bic/zrvk_grun = <source_fields>-reasn.
          RESULT_FIELDS-/bic/zrvk_abre = <fs>.
          APPEND RESULT_FIELDS TO RESULT_PACKAGE.
          CLEAR RESULT_FIELDS.
        ENDIF.
        int = int + 2. " начиная с 18 столбца через один находятся данные
      ENDDO.
    ENDLOOP.

holocron

тут, имхо, больше подходит:

Code:

do 80 times varying lv_var from <source_fields>-zzabrsn001 next <source_fields>-zzabrcsn002.
...
enddo.

при изменении структуры не надо будет менять цифру 18 хотя бы

lescha

holocron спасибо!

проблема в том, что в DataSoruce колонки <source_fields>-zzabrsn001... <source_fields>-zzabrsn001 находятся через одну...

а вот в другом проекте - то через одну, то через 3. Что можно в этом случае сделать???

заранее благодарен

murmur

схематично

Code:

DO 80 TIMES.
  DATA: 
    index TYPE n LENGTH 3,
    field_name TYPE string.

  index = sy-index.
  CONCATENATE 'ZZABRSN' index INTO field_name.
  
  ASSIGN COMPONENT field_name OF STRUCTURE <source_fields> TO <fs>.
  ...
ENDDO.

Abap в экспертной рутине

Кто сейчас на конференции