Текущее время: Чт, мар 28 2024, 21:16

Часовой пояс: UTC + 3 часа


Правила форума


ВНИМАНИЕ! Прежде чем задавать вопрос, ознакомьтесь со ссылками ниже:

Вопросы по отличиям версий SAP, Add-On, EHP - сюда
Вопросы по SAP Front End (SAPlogon, SAPgui, guiXT и т.д.) - сюда
Вопросы по LSMW - сюда
Вопросы по архивации в SAP - сюда
Вопросы по SAP GRC - сюда
Вопросы по SAP Business Workplace (почте SAP) и SAP Office - сюда
Вопросы по miniSAP (SAP mini basis) - сюда
Вопросы по SAP HANA - сюда
Вопросы по лицензированию продуктов SAP - сюда



Начать новую тему Ответить на тему  [ Сообщений: 5 ] 
Автор Сообщение
 Заголовок сообщения: DSWP_GET_SC_RESULTS
СообщениеДобавлено: Чт, сен 18 2014, 13:56 
Директор
Директор

Зарегистрирован:
Вт, ноя 09 2010, 19:59
Сообщения: 792
Откуда: Novosibirsk
Пол: Мужской
всем доброго времени суток!

может кто поделиться содержимым указанного объекта в солмане 7.1 после установки 12-го стэка ?

Цитата:
An exception occurred that is explained in detail below.
The exception, which is assigned to class 'CX_SY_REF_IS_INITIAL', was not caught in
procedure "DSWP_GET_SC_RESULTS" "(FUNCTION)", nor was it propagated by a RAISING clause.
Since the caller of the procedure could not have anticipated that the
exception would occur, the current program is terminated.
The reason for the exception is:
You attempted to use a 'NULL' object reference (points to 'nothing') access a component (variable: "SUBALERT_DEF").
An object reference must point to an object (an instance of a class) before it can be used to access components.
Either the reference was never set or it was set to 'NULL' using the CLEAR statement.


есть подозрение, что при установке стэка некоторые компоненты криво встали... :(


Пометить тему как нерешенную
Вернуться к началу
 Профиль  
 
 Заголовок сообщения: Re: DSWP_GET_SC_RESULTS
СообщениеДобавлено: Чт, сен 18 2014, 15:14 
Почетный гуру
Почетный гуру
Аватара пользователя

Зарегистрирован:
Чт, сен 28 2006, 11:36
Сообщения: 1365
Откуда: Москва
Пол: Мужской
а вгде оный искать?

этож процедура, не?


Пометить тему как нерешенную
Вернуться к началу
 Профиль  
 
 Заголовок сообщения: Re: DSWP_GET_SC_RESULTS
СообщениеДобавлено: Чт, сен 18 2014, 18:45 
Директор
Директор

Зарегистрирован:
Вт, ноя 09 2010, 19:59
Сообщения: 792
Откуда: Novosibirsk
Пол: Мужской
шрам написал:
а где оный искать?


Function Group = DSWP_EXECUTE_SD_SC -> Function modules


Пометить тему как нерешенную
Вернуться к началу
 Профиль  
 
 Заголовок сообщения: Re: DSWP_GET_SC_RESULTS  Тема решена
СообщениеДобавлено: Чт, сен 18 2014, 19:27 
Почетный гуру
Почетный гуру
Аватара пользователя

Зарегистрирован:
Чт, сен 28 2006, 11:36
Сообщения: 1365
Откуда: Москва
Пол: Мужской
Code:
FUNCTION dswp_get_sc_results.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(TECH_SYSTEMS) TYPE
*"        CL_DSWP_SD_HELPER=>TECHNICALSYSTEMS_TA OPTIONAL
*"     REFERENCE(SOLMAN_SYSTEM) TYPE  BOOLEAN OPTIONAL
*"     REFERENCE(IV_PERSIST_DATA) TYPE  BOOLEAN DEFAULT ABAP_TRUE
*"  EXPORTING
*"     REFERENCE(MESSAGES) TYPE  CL_DSWP_SD_HELPER=>EXT_MSG_DETAILS_TA
*"     REFERENCE(SYS_STATUS) TYPE  DSWPT_SYSTEM_RESULTS
*"     REFERENCE(EV_SOLMAN_STATUS) TYPE  MSGTY
*"----------------------------------------------------------------------
* ONE STRUCTURE FOR Status/Results
* another structure for messages

  TYPES:    BEGIN OF subalert_exec,
              sub_alert_guid TYPE dswpdnmguid,
              msg_duration   TYPE duration_sec,
              execution_num  TYPE dswpe_int,
              alert_id       TYPE dswp_sd_id,
              subalert_id    TYPE dswp_sd_id,
              context_ref    TYPE dswp_sd_exec-context_ref,
            END OF subalert_exec.

  TYPES: BEGIN OF lty_technical_systems,
          diagls_id TYPE diagls_id.
  TYPES: END OF lty_technical_systems.
  DATA lt_technical_systems TYPE TABLE OF lty_technical_systems.

  DATA: lv_tech_system TYPE diagls_id.
  DATA: lt_context_4_ts TYPE cl_dswp_sd_helper=>context_4_ts_ta.
  DATA: ls_context_4_ts TYPE cl_dswp_sd_helper=>context_4_ts.
  DATA: lt_context_refs TYPE cl_dswp_sd_helper=>context_4_ts_ta.
  DATA: ls_context_ref TYPE cl_dswp_sd_helper=>context_4_ts.
  DATA lt_msgs TYPE TABLE OF dswp_sd_msgs.
  DATA lt_messages LIKE lt_msgs.

  DATA: lt_sub_alert_exec_guids TYPE TABLE OF subalert_exec.
  DATA: ls_sub_alert_exec_guid TYPE subalert_exec.
  DATA: ls_msg TYPE dswp_sd_msgs.
  DATA: ls_action TYPE dswp_sd_msgs.
  DATA  no_of_messages TYPE i.
  DATA: current_message_no TYPE i.
  DATA: context_ref_ta TYPE TABLE OF dswpdnmguid.
  DATA: ll_msg TYPE symsg.
  DATA: ll_action TYPE symsg.
  DATA: msg_text TYPE string.
  DATA: msg_text2 TYPE string.
  DATA: msg_text3 TYPE string.
  DATA: action_text TYPE string.
  DATA: subalert_context_text TYPE string.
*  data: msg_type type string.
  DATA: msg_details TYPE cl_dswp_sd_helper=>message_details1.
  DATA: msg_duration TYPE duration_sec.
  DATA: msg TYPE string.
  DATA lt_sys_status TYPE dswpt_system_results.
  DATA ls_sys_status LIKE LINE OF lt_sys_status.
  DATA ls_system_set TYPE dswp_system_set.
  DATA lt_system_set TYPE TABLE OF dswp_system_set.
  DATA lr_dmd_model TYPE REF TO cl_dswp_sd_model_dmd.
  DATA alert_def TYPE REF TO cl_dswp_sd_model_alert_def.
  DATA subalert_def TYPE REF TO cl_dswp_sd_model_sub_alert_def.
  DATA alert_nam TYPE string.
  DATA subalert_nam TYPE string.
  DATA lv_system_id TYPE diagls_id.

  DATA lr_landscape_factory_lmdb  TYPE REF TO cl_diagls_factory.
  DATA ls_abap_solman_ts          TYPE sdiagls_abap_tech_syst.

  DATA ls_message TYPE symsg.

*customer message 347013 2014
  DATA lt_exec              TYPE  dswpt_exec.
  DATA ls_exec              LIKE LINE OF lt_exec.
  DATA lt_mess              TYPE  dswpt_msgs.
  DATA ls_mess              LIKE LINE OF lt_mess.
  DATA lt_context           TYPE  dswpt_context.
  DATA ls_context           LIKE LINE OF lt_context.
  DATA lt_stack             TYPE  dswpt_stack.
  DATA ls_technical_systems LIKE LINE OF lt_technical_systems.
  DATA ls_msgs              LIKE LINE OF lt_msgs.
  DATA ls_context_refs      LIKE LINE OF lt_context_refs.

  CLEAR ev_solman_status.

*  Update usage table
  CALL METHOD cl_dswp_data_manager=>update_usage_table.

  lr_dmd_model = cl_dswp_sd_model_dmd=>get_instance( ).

* IF ONLY THE solman_system is specified.
  IF solman_system NE abap_false.

    TRY.
        lr_landscape_factory_lmdb = cl_diagls_factory=>new_instance(
          im_implementation = cl_dswp_sd_constants=>c_lmdb ).

        CALL METHOD lr_landscape_factory_lmdb->get_sol_man_tech_systs
          IMPORTING
            ex_abap_tech_syst = ls_abap_solman_ts.

      CATCH cx_diagls_retrieve_exception.
    ENDTRY.

    ls_system_set-system_id = ls_abap_solman_ts-id.
    APPEND ls_system_set TO lt_system_set.
    CLEAR ls_system_set.
*    CONCATENATE sy-sysid '~' 'JAVA' INTO ls_system_set-system_id.
*    APPEND ls_system_set TO lt_system_set.
*    CLEAR ls_system_set.

    CLEAR messages.
    CLEAR: lt_context_refs, lt_sub_alert_exec_guids.
    SELECT context_ref context_type context_value FROM dswp_sd_context
          INTO CORRESPONDING FIELDS OF TABLE lt_context_4_ts
          FOR ALL ENTRIES IN lt_system_set
          WHERE tech_system = lt_system_set-system_id
          AND context_value = cl_dswp_sd_constants=>solman.

    SORT lt_context_4_ts BY context_ref.

    lt_context_refs = lt_context_4_ts.
    DELETE ADJACENT DUPLICATES FROM lt_context_refs COMPARING context_ref.

*  Get all exec guids at once
    IF lt_context_refs IS NOT INITIAL.
      SELECT sub_alert_exe_gd duration_exec execution_num alert_id subalert_id INTO TABLE lt_sub_alert_exec_guids
        FROM dswp_sd_exec FOR ALL ENTRIES IN lt_context_refs
        WHERE context_ref = lt_context_refs-context_ref.
    ENDIF.

    READ TABLE lt_context_4_ts INTO ls_context_4_ts INDEX 1.
    IF sy-subrc EQ 0.
      CONCATENATE subalert_context_text ls_context_4_ts-context_type ' = ' ls_context_4_ts-context_value  ' '
      INTO subalert_context_text.
    ENDIF.
*   Get all the guids
    IF lt_sub_alert_exec_guids IS NOT INITIAL.
      SELECT * FROM dswp_sd_msgs INTO TABLE lt_msgs
        FOR ALL ENTRIES IN lt_sub_alert_exec_guids
        WHERE sub_alert_exe_gd = lt_sub_alert_exec_guids-sub_alert_guid.

      lt_messages = lt_msgs.
    ENDIF.

    LOOP AT lt_sub_alert_exec_guids INTO ls_sub_alert_exec_guid.

      CLEAR msg_details.
      msg_duration = ls_sub_alert_exec_guid-msg_duration.

      CLEAR lt_msgs.
      lt_msgs = lt_messages.
*     Prepare messages of a sub-alert : message + action as one return message
      DELETE lt_msgs WHERE sub_alert_exe_gd <> ls_sub_alert_exec_guid-sub_alert_guid.

      IF lines( lt_msgs ) > 1.
        SORT lt_msgs BY msg_num DESCENDING.
      ENDIF.

      READ TABLE lt_msgs INDEX 1 INTO ls_msg.
      no_of_messages = ls_msg-msg_num.
      current_message_no = 0.
*     Get Alert and subalert definition from DMD
      CALL METHOD lr_dmd_model->get_alert_definition
        EXPORTING
          iv_alert_id  = ls_sub_alert_exec_guid-alert_id
        RECEIVING
          rr_alert_def = alert_def.

      CALL METHOD alert_def->get_short_text
        RECEIVING
          rv_short_text = alert_nam.

      CALL METHOD lr_dmd_model->get_subalert_definition
        EXPORTING
          iv_subalert_id  = ls_sub_alert_exec_guid-subalert_id
        RECEIVING
          rr_subalert_def = subalert_def.

      CALL METHOD subalert_def->get_description
        RECEIVING
          rv_description = subalert_nam.
*     Done so that message and its corresponding action go as one data
      DO no_of_messages TIMES.

        current_message_no = current_message_no + 1.
        CLEAR msg_text.
        CLEAR action_text.
        CLEAR msg_details.

        READ TABLE lt_msgs INTO ls_msg
             WITH KEY msg_num = current_message_no msg_action  = abap_false.
        IF sy-subrc = 0.

          CLEAR ls_message.
          MOVE-CORRESPONDING ls_msg TO ls_message.
          CALL METHOD cl_dswp_sd_helper=>get_message_documentation
            EXPORTING
              is_message = ls_message
              iv_langu   = sy-langu
            IMPORTING
              ev_text    = msg_text.


          msg_details-alert_id = ls_sub_alert_exec_guid-alert_id.
          msg_details-subalert_id = ls_sub_alert_exec_guid-subalert_id.
          msg_details-msgty = ls_msg-msgty.
          msg_details-message = msg_text.
          msg_details-context = subalert_context_text.
          msg_details-duration = msg_duration.
          msg_details-stack_trace = ls_msg-stacktraceguid.
          msg_details-tech_system = cl_dswp_sd_constants=>solman.
          msg_details-execution_num = ls_sub_alert_exec_guid-execution_num.
          msg_details-alert_definition = alert_nam.
          msg_details-subalert_definition = subalert_nam.
          msg_details-info_message = ls_msg-info_message.
        ENDIF.

        READ TABLE lt_msgs INTO ls_action
             WITH KEY msg_num = current_message_no msg_action = abap_true.
        IF sy-subrc = 0.
          CLEAR ls_message.
          MOVE-CORRESPONDING ls_action TO ls_message.
          CALL METHOD cl_dswp_sd_helper=>get_message_documentation
            EXPORTING
              is_message = ls_message
              iv_langu   = sy-langu
            IMPORTING
              ev_text    = msg_details-action.
        ENDIF.
        APPEND msg_details TO messages.
      ENDDO.

    ENDLOOP.
  ENDIF.

* Returns the solution manager system status if only solution manager is passed as input
  IF tech_systems IS INITIAL AND solman_system = abap_true.
    READ TABLE messages WITH KEY msgty = cl_dswp_sd_constants=>c_error_message TRANSPORTING NO FIELDS.
    IF sy-subrc = 0.
      ev_solman_status = cl_dswp_sd_constants=>c_error_message.
    ELSE.
      READ TABLE messages WITH KEY msgty = cl_dswp_sd_constants=>c_warning_message TRANSPORTING NO FIELDS.
      IF sy-subrc = 0.
        ev_solman_status = cl_dswp_sd_constants=>c_warning_message.
      ELSE.
        READ TABLE messages WITH KEY msgty = cl_dswp_sd_constants=>c_information_message TRANSPORTING NO FIELDS.
        IF sy-subrc = 0.
          ev_solman_status = cl_dswp_sd_constants=>c_information_message.
        ENDIF.
      ENDIF.
    ENDIF.
  ENDIF.

  CLEAR: lt_context_refs, lt_sub_alert_exec_guids.
  IF tech_systems IS INITIAL.
    RETURN.
  ENDIF.

  CLEAR messages.
  lt_technical_systems = tech_systems.

*  customer message 347013 2014: iv_persist data is set the result are read from DB , if it is not set we read from gloabl variables

  IF iv_persist_data = abap_false.
    CALL METHOD cl_dswp_self_check_impl=>get_results
      IMPORTING
        et_exec    = lt_exec
        et_msgs    = lt_mess
        et_context = lt_context
        et_stack   = lt_stack.
  ENDIF.

  IF iv_persist_data = abap_true.           " from DB

    SELECT * FROM dswp_sd_context
    INTO CORRESPONDING FIELDS OF TABLE lt_context_4_ts FOR ALL ENTRIES IN lt_technical_systems
    WHERE tech_system = lt_technical_systems-diagls_id AND context_value <> cl_dswp_sd_constants=>solman.

  ELSE.             "customer message 347013 2014  -> Reading from Global variable
    LOOP AT lt_technical_systems INTO ls_technical_systems.
      LOOP AT lt_context INTO ls_context WHERE tech_system = ls_technical_systems-diagls_id
        AND context_value <> cl_dswp_sd_constants=>solman.
        MOVE-CORRESPONDING ls_context TO ls_context_4_ts.
        APPEND ls_context_4_ts TO lt_context_4_ts.

      ENDLOOP.
    ENDLOOP.
    CLEAR ls_context_4_ts.
    CLEAR ls_technical_systems.
  ENDIF.

  SORT lt_context_4_ts BY context_ref.

  lt_context_refs = lt_context_4_ts.
  DELETE ADJACENT DUPLICATES FROM lt_context_refs COMPARING context_ref.

* Get all exec guids at once
  IF lt_context_refs IS NOT INITIAL.
    IF iv_persist_data = abap_true.         " from DB
      SELECT sub_alert_exe_gd duration_exec execution_num alert_id subalert_id context_ref INTO TABLE lt_sub_alert_exec_guids
        FROM dswp_sd_exec FOR ALL ENTRIES IN lt_context_refs
        WHERE context_ref = lt_context_refs-context_ref.

    ELSE.           "customer message 347013 2014  -> Reading from Global variable

      LOOP AT lt_context_refs INTO ls_context_refs.
        LOOP AT lt_exec INTO ls_exec WHERE context_ref = ls_context_refs-context_ref.

          ls_sub_alert_exec_guid-alert_id = ls_exec-alert_id.
          ls_sub_alert_exec_guid-context_ref = ls_exec-context_ref.
          ls_sub_alert_exec_guid-execution_num = ls_exec-execution_num.
          ls_sub_alert_exec_guid-sub_alert_guid = ls_exec-sub_alert_exe_gd.
          ls_sub_alert_exec_guid-subalert_id = ls_exec-subalert_id.
          ls_sub_alert_exec_guid-msg_duration = ls_exec-duration_exec.

          APPEND ls_sub_alert_exec_guid TO lt_sub_alert_exec_guids.
        ENDLOOP.
      ENDLOOP.
      CLEAR ls_context_refs.
      CLEAR ls_sub_alert_exec_guid.
    ENDIF.

  ENDIF.


* Get all the messages
  CLEAR lt_messages.
  IF lt_sub_alert_exec_guids IS NOT INITIAL.

    IF iv_persist_data = abap_true.                " from DB
      SELECT * FROM dswp_sd_msgs INTO TABLE lt_msgs
        FOR ALL ENTRIES IN lt_sub_alert_exec_guids
        WHERE sub_alert_exe_gd = lt_sub_alert_exec_guids-sub_alert_guid.

    ELSE.          "customer message 347013 2014  -> Reading from Global variable

      LOOP AT lt_sub_alert_exec_guids INTO ls_sub_alert_exec_guid.
        LOOP AT lt_mess INTO ls_mess  WHERE sub_alert_exe_gd = ls_sub_alert_exec_guid-sub_alert_guid.
          MOVE-CORRESPONDING ls_mess TO ls_msgs.
          APPEND ls_msgs TO lt_msgs.
        ENDLOOP.
      ENDLOOP.
      CLEAR ls_sub_alert_exec_guid.
      CLEAR ls_msgs.
    ENDIF.
    lt_messages = lt_msgs.
  ENDIF.

  LOOP AT lt_sub_alert_exec_guids INTO ls_sub_alert_exec_guid.

    READ TABLE lt_context_4_ts INTO ls_context_4_ts WITH KEY context_ref = ls_sub_alert_exec_guid-context_ref.
    CLEAR subalert_context_text.
    CONCATENATE subalert_context_text ls_context_4_ts-context_type ' = ' ls_context_4_ts-context_value  ' '
    INTO subalert_context_text.

    CLEAR lv_tech_system.
    READ TABLE lt_technical_systems INTO lv_tech_system WITH KEY diagls_id = ls_context_4_ts-tech_system.

    CLEAR msg_details.
    msg_duration = ls_sub_alert_exec_guid-msg_duration.

    CLEAR lt_msgs.
    lt_msgs = lt_messages.

*   Prepare messages of a sub-alert : message + action as one return message
    DELETE lt_msgs WHERE sub_alert_exe_gd <> ls_sub_alert_exec_guid-sub_alert_guid.

    IF lines( lt_msgs ) > 1.
      SORT lt_msgs BY msg_num DESCENDING.
    ENDIF.

    READ TABLE lt_msgs INDEX 1 INTO ls_msg.
    no_of_messages = ls_msg-msg_num.
    current_message_no = 0.

    CALL METHOD lr_dmd_model->get_alert_definition
      EXPORTING
        iv_alert_id  = ls_sub_alert_exec_guid-alert_id
      RECEIVING
        rr_alert_def = alert_def.

    CALL METHOD alert_def->get_short_text
      RECEIVING
        rv_short_text = alert_nam.

    CALL METHOD lr_dmd_model->get_subalert_definition
      EXPORTING
        iv_subalert_id  = ls_sub_alert_exec_guid-subalert_id
      RECEIVING
        rr_subalert_def = subalert_def.

    CALL METHOD subalert_def->get_description
      RECEIVING
        rv_description = subalert_nam.

    DO no_of_messages TIMES.

      current_message_no = current_message_no + 1.
      CLEAR msg_text.
      CLEAR action_text.
      CLEAR msg_details.

      READ TABLE lt_msgs INTO ls_msg
           WITH KEY msg_num = current_message_no msg_action  = abap_false.
      IF sy-subrc = 0.
        CLEAR ls_message.
        MOVE-CORRESPONDING ls_msg TO ls_message.
        CALL METHOD cl_dswp_sd_helper=>get_message_documentation
          EXPORTING
            is_message = ls_message
            iv_langu   = sy-langu
          IMPORTING
            ev_text    = msg_text.

        msg_details-alert_id = ls_sub_alert_exec_guid-alert_id.
        msg_details-subalert_id = ls_sub_alert_exec_guid-subalert_id.
        msg_details-msgty = ls_msg-msgty.
        msg_details-message = msg_text.
        msg_details-context = subalert_context_text.
        msg_details-duration = msg_duration.
        msg_details-stack_trace = ls_msg-stacktraceguid.
        msg_details-tech_system = lv_tech_system.
        msg_details-execution_num = ls_sub_alert_exec_guid-execution_num.
        msg_details-alert_definition = alert_nam.
        msg_details-subalert_definition = subalert_nam.
        msg_details-info_message = ls_msg-info_message.
      ENDIF.

      READ TABLE lt_msgs INTO ls_action
           WITH KEY msg_num = current_message_no msg_action = abap_true.
      IF sy-subrc = 0.
        CLEAR ls_message.
        MOVE-CORRESPONDING ls_action TO ls_message.
        CALL METHOD cl_dswp_sd_helper=>get_message_documentation
          EXPORTING
            is_message = ls_message
            iv_langu   = sy-langu
          IMPORTING
            ev_text    = msg_details-action.
      ENDIF.
      APPEND msg_details TO messages.
    ENDDO.

  ENDLOOP.

  CLEAR lt_system_set.
  CLEAR sys_status.
  SELECT system_id status last_run FROM dswp_system_set INTO CORRESPONDING FIELDS OF TABLE lt_system_set
  FOR ALL ENTRIES IN lt_technical_systems
  WHERE system_id = lt_technical_systems-diagls_id.

  LOOP AT lt_technical_systems INTO lv_tech_system.
    CLEAR ls_sys_status.
    READ TABLE lt_system_set INTO ls_system_set WITH KEY system_id = lv_tech_system.
    ls_sys_status-execution_date = ls_system_set-last_run.
    ls_sys_status-system_id      = lv_tech_system.
    ls_sys_status-status         = ls_system_set-status.
    APPEND ls_sys_status TO sys_status.
  ENDLOOP.
*
*  CLEAR lt_sys_status.
*  LOOP AT tech_systems INTO lv_tech_system.
*    CLEAR ls_sys_status.
*    SELECT SINGLE * FROM dswp_system_set INTO ls_system_set WHERE system_id = lv_tech_system.
*    ls_sys_status-execution_date = ls_system_set-last_run.
*    ls_sys_status-system_id = lv_tech_system.
*    ls_sys_status-status = ls_system_set-status.
*    APPEND ls_sys_status TO lt_sys_status.
*  ENDLOOP.
*  sys_status = lt_sys_status.
ENDFUNCTION.


Пометить тему как нерешенную
Вернуться к началу
 Профиль  
 
 Заголовок сообщения: Re: DSWP_GET_SC_RESULTS
СообщениеДобавлено: Чт, сен 18 2014, 21:12 
Директор
Директор

Зарегистрирован:
Вт, ноя 09 2010, 19:59
Сообщения: 792
Откуда: Novosibirsk
Пол: Мужской
шрам, спасибо!

отличается только относительно ноты Self-Diagnosis: Navigation to RCA Managed System UI generates the dumps которую впоследствии поставил


Пометить тему как нерешенную
Вернуться к началу
 Профиль  
 
Показать сообщения за:  Поле сортировки  
Начать новую тему Ответить на тему  [ Сообщений: 5 ] 

Часовой пояс: UTC + 3 часа


Кто сейчас на конференции

Сейчас этот форум просматривают: нет зарегистрированных пользователей


Вы не можете начинать темы
Вы не можете отвечать на сообщения
Вы не можете редактировать свои сообщения
Вы не можете удалять свои сообщения
Вы не можете добавлять вложения

Найти:
Перейти:  
cron
Powered by phpBB © 2000, 2002, 2005, 2007 phpBB Group
Русская поддержка phpBB