Форматирование числа в ALV-GRID

organmusic

Добрый день,
Можно ли пом параметра edit_mask (без написания своего конверсионного exitа) вывести отрицательное число в нормальном виде, например
-234567,58
(знак слева, десят разделитель - запятая)

Пока единственно что смог добиться
edit_mask = 'RRV__________.__'. выводит '- 13428.56'

или писать свой CONVERSION_EXIT (может есть уже готовый?)

Спасибо!

N/A

Цитата:

Пока единственно что смог добиться
edit_mask = 'RRV__________.__'. выводит '- 13428.56'

Точка здесь из системных настроек юзера. Если критично SU01 - выбрать нужный формат с запятой

AndreyV

N/A написал(а):

Цитата:

Пока единственно что смог добиться
edit_mask = 'RRV__________.__'. выводит '- 13428.56'

Точка здесь из системных настроек юзера. Если критично SU01 - выбрать нужный формат с запятой

Проблема здесь не в точке, можно и так написать
'RRV__________,__', а в количестве пробелов между знаком минус и самим числом.
С этим вероятно никак не побороться в ALV, пишите свой CONVERSION_EXIT_Zxxx_OUTPUT.

organmusic

В общем написал свой CONVERSION_EXIT
Может кому подойдет
Группа функций ZSIGN:

Цитата:

FUNCTION CONVERSION_EXIT_ZSIGN_OUTPUT.
*"----------------------------------------------------------------------
*"*"Локальный интерфейс:
*" IMPORTING
*" VALUE(INPUT)
*" EXPORTING
*" VALUE(OUTPUT)
*"----------------------------------------------------------------------
DATA:
dec TYPE I,
out TYPE I,
msk TYPE STRING,
smp TYPE STRING VALUE '____________________',
buf(30) TYPE C.

DESCRIBE FIELD input DECIMALS dec.
DESCRIBE FIELD input OUTPUT-LENGTH out.
out = out - dec - 1.
CONCATENATE 'RRV' smp(out) '.' smp(dec) INTO msk.
WRITE input TO buf USING EDIT MASK msk.
CONDENSE buf NO-GAPS.
TRANSLATE buf USING '.,'.
SHIFT buf LEFT DELETING LEADING space.
output = buf.
SHIFT output RIGHT DELETING TRAILING space.
ENDFUNCTION.

Далее - В описаниии поля alv:

Цитата:

it_cat-edit_mask = '==ZSIGN'.

и все в порядке
(можно наверное и короче написать)

sibrin

Можно вместо того, чтобы edit mask составлять, просто написать
write input to l_char no-SIGN.
а потом
if input < 0. concatenate '-' input into output. endif.
Ну и shift, по вкусу.

organmusic

sibrin написал:

Можно вместо того, чтобы edit mask составлять, просто написать
write input to l_char no-SIGN.
а потом
if input < 0. concatenate '-' input into output. endif.
Ну и shift, по вкусу.

Последняя (исправленная) версия экзита:

Code:

FUNCTION CONVERSION_EXIT_ZSIGN_OUTPUT.
*"----------------------------------------------------------------------
*"*"Локальный интерфейс:
*"  IMPORTING
*"     VALUE(INPUT)
*"  EXPORTING
*"     VALUE(OUTPUT)
*"----------------------------------------------------------------------
  WRITE input TO output NO-SIGN NO-GROUPING LEFT-JUSTIFIED.
  IF ( input < 0 ).
    CONCATENATE '-' output INTO output.
  ENDIF.
  SHIFT output RIGHT DELETING TRAILING space.
ENDFUNCTION.

Всего доброго!

Правила форума

Форматирование числа в ALV-GRID

Кто сейчас на конференции