VBA в BEx: Вызов макроса при сохранении раб.книги

ria

Добрый день!

Подскажите пожалуйста, как реализовать вызов макроса при нажатии на стандартную кнопку панели инструментов BEx'а "Сохранить существующую рабочую книгу"?
К примеру, для кнопки "Обновить запрос" аналогичный вызов прописывали в модуле SAPBEX так:

Sub SAPBEXonRefresh(queryID As String, resultArea As Range)
Call plan_SAPBEXonRefresh(queryID, resultArea)
End Sub

Заранее спасибо

ken

Добрый день!

Думаю что нельзя так сделать на уровне рабоочей книги, потому что в параметрах рабочих книг имеется только запуск макроса при актуализации, других событий не предусмотрено.

ria

Спасибо за ответ!
А свою кнопку в панель инструментов BEx'а добавить можно?

ken

Думаю можно добавить ещё одну свою надстройку со своими кнопками в Excel.

Faron

ria написал(а):

Спасибо за ответ!
А свою кнопку в панель инструментов BEx'а добавить можно?

Можно в надстойку. Примерно так:

Code:

Const pAction As String = "NewButton"
Const pCaption As String = "NewButton"

Private Sub Workbook_Activate()
  Call createButton
End Sub

Private Sub Workbook_Deactivate()
  Call deleteButton
End Sub

Private Sub Workbook_WindowActivate(ByVal Wn As Window)
  Call createButton
End Sub
Private Sub Workbook_WindowDeActivate(ByVal Wn As Window)
  Call deleteButton
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
  If Cancel = True Then
    Call deleteButton
  End If
End Sub

Private Sub Workbook_Open()
 For Each cb In Application.CommandBars
    If cb.Name = "Interface" Then
       cb.Delete
       Exit For
     End If
 Next cb
 Call createButton
End Sub

Public Sub SetSBOButtonProps(ByVal lVisibility As Boolean)
  With Application.CommandBars("Interface")
    .Visible = lVisibility
  End With
  With Application.CommandBars("Interface").Controls(1)
    .OnAction = pAction
    .Caption = pCaption
  End With
End Sub

Sub createButton()

 Dim cb, myBar

 For Each cb In Application.CommandBars
    If cb.Name = "RestForms" Then
       cb.Delete
     End If
 Next cb

 Set myBar = Application.CommandBars _
    .Add(Name:="RestForms", Position:=msoBarTop, Temporary:=True)
  Set Newitem = myBar.Controls.Add(Type:=msoControlButton)
 With Newitem
    .Caption = pCaption
    .FaceId = 271
    .OnAction = pAction
    .Style = msoButtonIconAndCaption
    .Enabled = True
 End With
  myBar.Visible = True
 End Sub

Sub deleteButton()
 Dim cb
 For Each cb In Application.CommandBars
    If cb.Name = "RestForms" Then
       cb.Delete
       Exit For
     End If
 Next cb
End Sub

VBA в BEx: Вызов макроса при сохранении раб.книги

Кто сейчас на конференции