Вырезать текст между символами { }

toshka1993

Необходимо вырезать слово между символами { }. Причем таких слов в строке может быть несколько, и строка может быть любая. Например,
txt = ` {BODY} ` или txt = `12asd{HEAD}1a {BODY}asd`
Пробовала сделать с помощью регулярных выражений, но получилось вырезать, если строка с пробелами (txt = ` {BODY} `)
Как можно такое реализовать?

Удав

Как пример:

Code:

  WHILE sy-subrc = 0 AND p_str IS NOT INITIAL.
    SEARCH p_str FOR '{' IN CHARACTER MODE.
    CHECK sy-subrc = 0.
    lv_start = sy-fdpos - 1. "Если требуется удалять кавычки
    SEARCH p_str FOR '}' IN CHARACTER MODE.
    CHECK sy-subrc = 0.
    lv_end = sy-fdpos + 1. "Если требуется удалять кавычки
    lv_str = lv_str && p_str(lv_start).
    p_str = p_str+lv_end.
  ENDWHILE.
  IF p_str IS NOT INITIAL.
    lv_str = lv_str && p_str.
  ENDIF.
 

toshka1993

Удав написал(а):

Как пример:

Code:

  WHILE sy-subrc = 0 AND p_str IS NOT INITIAL.
    SEARCH p_str FOR '{' IN CHARACTER MODE.
    CHECK sy-subrc = 0.
    lv_start = sy-fdpos - 1. "Если требуется удалять кавычки
    SEARCH p_str FOR '}' IN CHARACTER MODE.
    CHECK sy-subrc = 0.
    lv_end = sy-fdpos + 1. "Если требуется удалять кавычки
    lv_str = lv_str && p_str(lv_start).
    p_str = p_str+lv_end.
  ENDWHILE.
  IF p_str IS NOT INITIAL.
    lv_str = lv_str && p_str.
  ENDIF.
 

Спасибо большое!
Но проблема еще в том, что && со строками в моей системе не работает

trop

Code:

data text type string.
text = your_text_variable.  " при работе с regex лучше преобразов. предвар. в string
replace all occurrences of regex `\{[^\}]+\}` in text with ``.

toshka1993

trop написал(а):

Code:

data text type string.
text = your_text_variable.  " при работе с regex лучше преобразов. предвар. в string
replace all occurrences of regex `\{[^\}]+\}` in text with ``.

Спасибо большое!=) работает! только мне нужно получить слова, которые в скобках и отдельно, а не одной строкой

Удав

toshka1993 написал(а):

Но проблема еще в том, что && со строками в моей системе не работает

Используйте оператор CONCATENATE.

toshka1993

Удав написал(а):

toshka1993 написал(а):

Но проблема еще в том, что && со строками в моей системе не работает

Используйте оператор CONCATENATE.

спасибо=)

Gustav

toshka1993 написал(а):

мне нужно получить слова, которые в скобках и отдельно, а не одной строкой

Code:

DATA txt        TYPE string.
DATA it_matches TYPE match_result_tab.
DATA wa_matches LIKE LINE OF it_matches.
DATA it_subs    TYPE submatch_result_tab.
DATA wa_subs    LIKE LINE OF it_subs.

START-OF-SELECTION.

  txt = `12asd{HEAD}1a {BODY} asd  { BODY BUILDER} `.

  FIND ALL OCCURRENCES OF REGEX '\{([^\{]+)\}' IN txt RESULTS it_matches.

  LOOP AT it_matches INTO wa_matches.
    WRITE: / txt+wa_matches-offset(wa_matches-length).
    it_subs = wa_matches-submatches.
    LOOP AT it_subs INTO wa_subs.
      WRITE: txt+wa_subs-offset(wa_subs-length).
    ENDLOOP.
  ENDLOOP.

{HEAD} HEAD
{BODY} BODY
{ BODY BUILDER} BODY BUILDER

toshka1993

Gustav написал:

toshka1993 написал(а):

мне нужно получить слова, которые в скобках и отдельно, а не одной строкой

Code:

DATA txt        TYPE string.
DATA it_matches TYPE match_result_tab.
DATA wa_matches LIKE LINE OF it_matches.
DATA it_subs    TYPE submatch_result_tab.
DATA wa_subs    LIKE LINE OF it_subs.

START-OF-SELECTION.

  txt = `12asd{HEAD}1a {BODY} asd  { BODY BUILDER} `.

  FIND ALL OCCURRENCES OF REGEX '\{([^\{]+)\}' IN txt RESULTS it_matches.

  LOOP AT it_matches INTO wa_matches.
    WRITE: / txt+wa_matches-offset(wa_matches-length).
    it_subs = wa_matches-submatches.
    LOOP AT it_subs INTO wa_subs.
      WRITE: txt+wa_subs-offset(wa_subs-length).
    ENDLOOP.
  ENDLOOP.

{HEAD} HEAD
{BODY} BODY
{ BODY BUILDER} BODY BUILDER

спасибо большое!=) то, что нужно!=)

camelotka

Один из многих вариантов, как это можно сделать:

Code:

DATA : lt_substr  TYPE STANDARD TABLE OF string,
       lv_sym1(1)             VALUE '{',
       lv_sym2(1)             VALUE '}',
       ls_str     TYPE string VALUE '12asd{HEAD}1a {BODY}asd'.

FIELD-SYMBOLS :
       <ls_substr> LIKE LINE OF lt_substr.
" Делим строку так чтобы начало нужной подстроки попало в начало отдельной строки
" Строка распилена в отдельную таблицу lt_substr
SPLIT ls_str AT lv_sym1 INTO TABLE lt_substr.
" Разбираем таблицу построчно
LOOP AT lt_substr ASSIGNING <ls_substr>.
  SEARCH <ls_substr> FOR lv_sym2.           "Ищем в строке закрывающий символ
  IF sy-subrc NE 0.                         "1. Если не найден
    DELETE lt_substr INDEX sy-tabix.        " Удаляем строку
    sy-tabix = sy-tabix - 1.                " Смещаем индекс
                                            "/ не хорошо изменять напрямую sy-tabix
                                            " - лучше переложить в свою переменную
  ELSE.
    <ls_substr> = <ls_substr>+0(sy-fdpos).  "2. Если найден перекладываем в строку
                                            " только тот кусок строки что нам нужен
                                            " sy-fdpos хранит позицию найденого символа
  ENDIF.
ENDLOOP.

Правила форума

Вырезать текст между символами { }

Кто сейчас на конференции