Batch Input в MM02 как выбрать ракурс

Galka

Смысл в чем: надо вводить данные в закладку "Бухгалтерский учет 2"
При запуске MM02 надо выбрать ракурс(т.е. закладку). Ракурсов может быть предложено неизвестное количество (зависит от настроек - я встречала 22 и 29). Нужно выбрать именно Бухучет2 (Accounting 2/Buchhaltung 2).
Вот примерная запись:

Code:

perform bdc_dynpro      using 'SAPLMGMM' '0070'.
*perform bdc_field       using 'BDC_CURSOR'
*                              'MSICHTAUSW-DYTXT(01)'.
perform bdc_field       using 'BDC_OKCODE'
                              '=RESA'. " отщелкнула выбранное

perform bdc_dynpro      using 'SAPLMGMM' '0070'.
*perform bdc_field       using 'BDC_CURSOR'
*                              'MSICHTAUSW-DYTXT(01)'.
perform bdc_field       using 'BDC_OKCODE'
                              '=P+'. " page down

perform bdc_dynpro      using 'SAPLMGMM' '0070'.
*perform bdc_field       using 'BDC_CURSOR'
*                              'MSICHTAUSW-DYTXT(08)'.
perform bdc_field       using 'BDC_OKCODE'
                              '=ENTR'.
perform bdc_field       using 'MSICHTAUSW-KZSEL(08)'
                              record-KZSEL_08_002. "выбрала строку

Есть конечно вариант выбирать первую строку и там уже переходить по закладкам - но возникает та же проблема

Сергей Королев

Лучше пользоваться функцией MATERIAL_MAINTAIN_DARK

РМщик

Code:

REPORT  ZTEST2021                               .

DATA:   BDCDATA LIKE BDCDATA    OCCURS 0 WITH HEADER LINE.

PARAMETERS: MATNR LIKE MARA-MATNR OBLIGATORY ,
            WERKS TYPE WERKS_D MEMORY ID WRK OBLIGATORY.

PERFORM BDC_DYNPRO      USING 'SAPLMGMM' '0060'.
PERFORM BDC_FIELD       USING 'BDC_CURSOR'
                              'RMMG1-MATNR'.
PERFORM BDC_FIELD       USING 'RMMG1-MATNR'
                              MATNR.
PERFORM BDC_DYNPRO      USING 'SAPLMGMM' '4000'.

SET PARAMETER ID 'WRK' FIELD WERKS.
SET PARAMETER ID 'MXX' FIELD 'B'.  "  Вся изюминка :)

CALL TRANSACTION 'MM02' USING BDCDATA MODE 'E'.

*&---------------------------------------------------------------------*
*&      Form  BDC_DYNPRO
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->PROGRAM    text
*      -->DYNPRO     text
*----------------------------------------------------------------------*
FORM BDC_DYNPRO USING PROGRAM DYNPRO.
  CLEAR BDCDATA.
  BDCDATA-PROGRAM  = PROGRAM.
  BDCDATA-DYNPRO   = DYNPRO.
  BDCDATA-DYNBEGIN = 'X'.
  APPEND BDCDATA.
ENDFORM.                    "BDC_DYNPRO

FORM BDC_FIELD USING FNAM FVAL.
    CLEAR BDCDATA.
    BDCDATA-FNAM = FNAM.
    BDCDATA-FVAL = FVAL.
    APPEND BDCDATA.
ENDFORM.

Вольдемар

Что это за параметр - 'МХХ' ? Индекс ракурса? А какие ещё значения бывают? И, кстати, как проверить, что ракурс уже создан?

РМщик

вот некоторые:

A - подготовка производства
B - бухгалтерский учет
C - классификация
D - ППМ1
G - калькуляция 1
K - основные данные 1
L - ДанЗавода/Складиров1
P - прогноз
S - управление складами 1
V - Сбыт: СБытОрганиз 1
X - заводской запас
Z - складской запас

нужно помнить, что для некоторых ракурсов нужно доп.задавать параметры.
В вышестоящем примере - завод, а могут потребоваться склад и т.д.

ну, а выбор ракурсов... напишу чуть позже

РМщик

по этим наименованием - см поля PSTAT, VPSTA
в табличке MARA для заданного материала

и можно определить - какие ракурсы существуют к материалу

Galka

Спасибо, PMщик, за помощь.

To OlegDm - я думала почти так сделать, можно было бы и программно изменить настройки - но во-первых я не знаю, сколько полей будет в системе пользователя, а если не программно - снабдить прогу комментариями типо "дорогой пользователь, прежде чем запустить программу, замените такие-то настройки" - не серьезно.

Да и проблема - как запомнить старые настройки и программно настроить их после завершения прогона.

В конце концов было сделано так:

Code:

 CALL FUNCTION 'MATERIAL_BTCI_SELECTION_NEW'
    EXPORTING
      material                  = ih_intab-matnr
      selection                 = 'B'
      tcode                     = 'MM02'
    TABLES
      btci_d0070                = bdcdata_2
    EXCEPTIONS
      material_not_found        = 1
      material_number_missing   = 2
      material_type_missing     = 3
      material_type_not_found   = 4
      no_active_dynpro_selected = 5
      no_authority              = 6
      OTHERS                    = 7.

  IF sy-subrc IS INITIAL.
    READ TABLE bdcdata_2 WITH KEY fval = 'X'.
    ind = bdcdata_2-fnam+17(2) + 1.
  ENDIF.

  IF ind > 17.
    PERFORM bdc_dynpro      USING 'SAPLMGMM' '0070'.
    PERFORM bdc_field       USING 'BDC_OKCODE'
                                  '=P+'.
    ind = ind - 17.
  ENDIF.
  n = ind.

  CLEAR temp_str.
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0070'.

  CONCATENATE 'MSICHTAUSW-KZSEL(' n ')' INTO temp_str.

  PERFORM bdc_field       USING 'BDC_CURSOR' temp_str.
  PERFORM bdc_field       USING temp_str 'X'.
  PERFORM bdc_field       USING 'BDC_OKCODE' '=ENTR'.

  PERFORM bdc_dynpro      USING 'SAPLMGMM' '0080'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                'ENTR'.
  CLEAR temp_str.
  WRITE s_werks-low TO temp_str.
  PERFORM bdc_field       USING 'RMMG1-WERKS'
                                 temp_str.
  PERFORM bdc_dynpro      USING 'SAPLMGMM' '4000'.
  PERFORM bdc_field       USING 'BDC_OKCODE'
                                '=BU'.
  CLEAR temp_str1.
  WRITE ih_intab-bwprh  TO  temp_str1 CURRENCY waers.
  PERFORM bdc_field       USING 'MBEW-BWPRH'
                                temp_str1.
  CLEAR temp_str1.
  WRITE ih_intab-bwph1  TO  temp_str1 CURRENCY waers.
  PERFORM bdc_field       USING 'MBEW-BWPH1'
                                temp_str1.
  CLEAR temp_str1.
  WRITE ih_intab-vjbwh  TO  temp_str1 CURRENCY waers.
  PERFORM bdc_field       USING 'MBEW-VJBWH'
                                temp_str1.
  CLEAR temp_str2.
  WRITE ih_intab-bwpei  TO  temp_str2.
  PERFORM bdc_field       USING 'MBEW-BWPEI'
                                temp_str2.

Тема старая, поэтому не поднимаю наверх, а редактирую.

Эта функция MATERIAL_BTCI_SELECTION_NEW возвращает все ракурсы для материала и отмечает Х ракурсы выбранного статуса.

OlegDm

поэтому то я и грохнул свой пост, тем более в памяти отложилось, что вроде так работало, а проверил... упс :roll:

Правила форума

Batch Input в MM02 как выбрать ракурс

Кто сейчас на конференции