Группова обработка записей внутренней таблицы

Geolog

Есть внутренняя табличка:
докумет позиция условный_номер
1000000 10 3
1000000 20 3
2000000 10 5
2000000 20 5
Не подскажите, как проще всего обработать записи с одинаковым уловным_номером? Т.е. для позиций документов, у которых поле условный_номер = 3 нужно вызвать, например, подпрограмму, в которой они обработаются, этой же подпрограммой нужно обработать группу позиций с условным_номером 5 и т.д.

qwerty

Создать отдельную таблицу, которая бы содержала варианты заполнения поля "условный_номер". Затем выполнить внешний цикл по этой таблице, внутренний цикл с условием по твоей.

Сергей Королев

А чем обычный CASE не устраивает?

Code:

LOOP AT itab.
  CASE itab-num.
    WHEN '3'.
      PERFORM subroutine_3.
    WHEN '5'.
      PERFORM subroutine_3.
    ....
  ENDCASE.
ENDLOOP.

Geolog

Номера разные могут быть... может 3 и 5, а может 87. Всех вариантов не переберешь.
Вообщем "условный_номер" - это просто признак группировки записей. Если он меняется, то пошла другая группа и для нее своя обработка.

T

Code:

types: begin of itab_str_type,
         num(10),
         pos(6),
         group(2),
       end of itab_str_type.

types: itab_type type table of itab_str_type.

data: itab type itab_type with header line.
data: itab_part type itab_type.
data: wa like line of itab.

data: index like sy-tabix.

START-OF-SELECTION.

itab = '000000001000000101'.
append itab.

itab = '000000001000000201'.
append itab.

itab = '000000002000000203'.
append itab.

itab = '000000002000000102'.
append itab.

itab = '000000002000000202'.
append itab.

itab = '000000001000000301'.
append itab.

sort itab by group.


loop at itab.

  index = sy-tabix + 1.

  append itab to itab_part.

  read table itab into wa index index.
  if sy-subrc <> 0 or wa-group <> itab-group.
    perform processing tables itab_part.
    refresh itab_part.
  endif.

endloop.
*&---------------------------------------------------------------------*
*&      Form  processing
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_ITAB_PART  text
*----------------------------------------------------------------------*
FORM processing TABLES   PT_ITAB type itab_type.
  loop at PT_ITAB.
    write: / PT_ITAB-NUM, PT_ITAB-POS, PT_ITAB-GROUP.
  endloop.
  skip.

ENDFORM.                    " processing

T

Если есть возможность поместить группировочное поле на первое место в структуре, то можно и так:

Code:

types: begin of itab_str_type,
         group(2),
         num(10),
         pos(6),
       end of itab_str_type.

types: itab_type type table of itab_str_type.

data: itab type itab_type with header line.
data: itab_part type itab_type.

START-OF-SELECTION.

itab = '010000000010000001'.
append itab.

itab = '010000000010000002'.
append itab.

itab = '020000000010000002'.
append itab.

itab = '030000000010000002'.
append itab.

itab = '020000000010000002'.
append itab.

itab = '010000000010000002'.
append itab.

sort itab by group.

loop at itab.

  append itab to itab_part.

  at end of group.
    perform processing tables itab_part.
    refresh itab_part.
  endat.

endloop.

FORM processing TABLES   PT_ITAB type itab_type.
  loop at PT_ITAB.
    write: / PT_ITAB-NUM, PT_ITAB-POS, PT_ITAB-GROUP.
  endloop.
  uline.
ENDFORM.                    " processing

Сергей Королев

Geolog написал(а):

Номера разные могут быть... может 3 и 5, а может 87. Всех вариантов не переберешь.
Вообщем "условный_номер" - это просто признак группировки записей. Если он меняется, то пошла другая группа и для нее своя обработка.

ну так можно параметры и через SELECT-OPTIONS задать, что типа того:

Code:

LOOP AT itab.
  IF itab-num IN sopt1.
    PERFORM subroutine1.
  ELSEIF itab-num IN sopt2.
    PERFORM subroutine2.
  .......
  ENDIF.
ENDLOOP.

Geolog

Не пойдет. Таблица уже есть - заполнена пользователем на экране, например:
материал группа
a 3
b 3
c 6
d 6
e 7

Теперь нужно обработать записи по группам, согласно значению признака группировки "группа".

slash

LOOP AT itab WHERE если для одной группы,
если для всех, то так, как писал Сергей Королёв

artyom

Geolog написал(а):

Не пойдет. Таблица уже есть - заполнена пользователем на экране, например:
материал группа
a 3
b 3
c 6
d 6
e 7

Теперь нужно обработать записи по группам, согласно значению признака группировки "группа".

Если есть уже связь м-ду условным номером и обработчиком - то просто делай loop и вызывай обработку динамически.

artyom

Типа такого

Цитата:

REPORT ZFM_DINAM_PERFORM_TEST .
data: begin of zzz occurs 10,
numb(10) type c,
perf(30) type c,
end of zzz.

data: begin of xxx occurs 10,
numb(10) type c,

end of xxx.

zzz-numb = 1.
zzz-perf = 'PERF1'.
append zzz.

zzz-numb = 2.
zzz-perf = 'PERF2'.
append zzz.

zzz-numb = 3.
zzz-perf = 'PERF1'.
append zzz.

xxx-numb = 1.
append xxx.
xxx-numb = 3.
append xxx.
xxx-numb = 2.
append xxx.

loop at xxx.
read table zzz with key numb = xxx-numb.
PERFORM (zzz-perf) IN PROGRAM ZART_DIN.
endloop.

form perf1.
write:/ 'PERF1'.
endform.
form perf2.
write:/ 'PERF2'.
endform.

[/code]

Geolog

Спасибо за отзывы.

abaper

Извините старика, не удержался от комментариев...

Господин Т ответил абсолютно правильно и исчерпывающе в обеих ответах - respect. Весь остальной флейм, вы уж не обижайтесь, какая-то шняга.

А вам, господин Геолог - минус, учите матчасть! :wink:

Stenj_90

Полность согласен с тем, что решения, предложенные господином Т, приведут к требуемому результату. Но часто невозможно выполнить предварительную сортировку. Например нужна групповая обработка записей после радактирования в гриде и возвращение обратно в грид при ошибке (материала не хватило на складе для выдачи на несколько разных ОС). Некрасиво увидеть пересортированные записи. Можно перед обработкой перегрузить во временную таблицу, но тогда имеет смысл сразу ее делать сортированной и потеряем связку с записями исходной таблицы (по крайней мере без изощрений) хотя-бы для раскрашивания красным цветом ячеек кол-ва. А можно работать со строками напрямую, сохранив их номера:

Code:

types: begin of itab_str_type,
         num(10),
         pos(6),
         group(2),
       end of itab_str_type.

types: itab_type type table of itab_str_type.

data: itab type itab_type with header line.

data: begin of wa_tabix,
        tabix       like sy-tabix,
      end   of wa_tabix.

data: begin of wa_group,
        group       type itab_str_type-group,
        iTabix      like table of wa_tabix,
      end   of wa_group.

data: it_group like sorted table of wa_group
               with unique key group.

field-symbols: <fs> like line of it_group.

data : nTabix       like sy-tabix.

START-OF-SELECTION.

  itab = '000000001000000101'.
  append itab.

  itab = '000000001000000201'.
  append itab.

  itab = '000000002000000203'.
  append itab.

  itab = '000000002000000102'.
  append itab.

  itab = '000000002000000202'.
  append itab.

  itab = '000000001000000301'.
  append itab.

  loop at itab.
    nTabix = sy-tabix.
    read table it_group assigning <fs>
               with table key group = itab-group.
    if sy-subrc = 0.
      clear: wa_tabix.
      wa_tabix-tabix = nTabix.
      append wa_tabix to <fs>-iTabix.
      modify table it_group from <fs> transporting iTabix.
    else.
      clear: wa_group, wa_tabix.
      refresh: wa_group-iTabix.
      wa_group-group = itab-group.
      wa_tabix-tabix = nTabix.
      append wa_tabix to wa_group-iTabix.
      insert wa_group into table it_group.
    endif.
  endloop.

  loop at it_group assigning <fs>.
    perform processing tables itab using <fs>.
  endloop.

*---------------------------------------------------------------------*
*       FORM processing                                               *
*---------------------------------------------------------------------*
form processing tables itab     type itab_type
                using  wa_group like line of it_group.

  data: wa_tabix like line of wa_group-iTabix.

  loop at wa_group-iTabix into wa_tabix.
    read table itab index wa_tabix-tabix.
    write: / itab-NUM, itab-POS, itab-GROUP.
  endloop.
  skip.

endform.

T

2 Stenj_90
Ну если в такой постановке, то ясен перец надо менять подход

Идею понял, но где-то тут был мой напильник.. :wink:

Code:

types: begin of itab_str_type,
         num(10),
         pos(6),
         group(2),
       end of itab_str_type.

types: itab_type type table of itab_str_type.

data: itab type itab_type with header line.

data: begin of wa_group,
        group       type itab_str_type-group,
        iTabix      type table of tabix,
      end   of wa_group.

data: it_group like sorted table of wa_group
               with unique key group.

field-symbols: <fs> like line of it_group.

data : nTabix       like sy-tabix.

START-OF-SELECTION.

  itab = '000000001000000101'.
  append itab.

  itab = '000000001000000201'.
  append itab.

  itab = '000000002000000203'.
  append itab.

  itab = '000000002000000102'.
  append itab.

  itab = '000000002000000202'.
  append itab.

  itab = '000000001000000301'.
  append itab.

  loop at itab.
    nTabix = sy-tabix.
    read table it_group assigning <fs>
               with table key group = itab-group.
    if sy-subrc = 0.
      append nTabix to <fs>-iTabix.
    else.
      clear: wa_group.
      wa_group-group = itab-group.
      append nTabix to wa_group-iTabix.
      insert wa_group into table it_group.
    endif.
  endloop.

  loop at it_group assigning <fs>.
    perform processing tables itab <fs>-iTabix.
  endloop.

*---------------------------------------------------------------------*
*       FORM processing                                               *
*---------------------------------------------------------------------*
form processing tables itab     type itab_type
                       pt_index like wa_group-iTabix.

  loop at pt_index.
    read table itab index pt_index.
    write: / itab-NUM, itab-POS, itab-GROUP.
  endloop.
  skip.

endform.

ЗЫ Пятница

Правила форума

Группова обработка записей внутренней таблицы

Кто сейчас на конференции