Вопрос на засыпку :)))

Igor Garanichev

Доброе время суток.

Как из SAP узнать, какие региональные настройки у пользователя?
В частности, интересует разделитель дробной и целой части.
Операционная система из линейки WINDOWS.

slash

уже было
cl_gui_frontend_services - может там тоже есть

Igor Garanichev

slash написал(а):

уже было
cl_gui_frontend_services - может там тоже есть

А что это?

slash

=)
cl_ = class

Parazit

Только надо иметь ввиду, что, например, Excel 2003 может и не использовать настройки Windows.

Parazit

Я делал так:

Code:

  DATA:
    HKEY_CURRENT_USER TYPE I VALUE 1.

  CALL FUNCTION 'GUI_GET_REGVALUE'
       EXPORTING
            ROOT           = HKEY_CURRENT_USER
            KEY            = 'Control Panel\International'
            VALUE_NAME     = 'sDecimal'
       CHANGING
            STRING         = RESULT
       EXCEPTIONS
            REGISTRY_ERROR = 1.

ABC

А еще разделитель дробной и целой части настраивается в User Profile'e (su3).
GUI_UPLOAD для выяснения данного вопроса использует такой незатейливый способ:

Code:

  DATA: strDecimal  TYPE C,
        nPacked     TYPE P DECIMALS 2 VALUE 0,
        strTemp(10) TYPE C.

  " Determine decimal delimiter
  CLEAR strtemp.
  WRITE nPacked TO strtemp(10).
  SEARCH strtemp FOR ','.
  IF SY-SUBRC EQ 0.
    strDecimal = ','.
  ELSE.
    strDecimal = '.'.
  ENDIF.

sibrin

Code:

  DATA: dcpfm LIKE usr01-dcpfm
      , dsr(1)
      , dsd(1)
  .

  SELECT SINGLE dcpfm INTO dcpfm FROM usr01 WHERE bname = sy-uname.
  IF dcpfm = ''.
    dsr = '.'. dsd = ','.
  ELSEIF dcpfm = 'X'.
    dsr = ','. dsd = '.'.
  ELSEIF dcpfm = 'Y'.
    dsr = ' '. dsd = ','.
  ENDIF.

sy-uname

ABC написал(а):

А еще разделитель дробной и целой части настраивается в User Profile'e (su3).
GUI_UPLOAD для выяснения данного вопроса использует такой незатейливый способ:

Code:

...  WRITE nPacked TO strtemp(10).
...

Это способ выяснить настройки фронтенда, которые могут отличаться от настроек Windows, Excel и т.п.

sy-uname

Для Excel, Wodr и пр. с чем можно работать через DOI можно воспользоваться следующим
I_OI_DOCUMENT_PROXY метод GET_APPLICATION_PROPERTY

Code:

    data: PROXY                 type ref to I_OI_DOCUMENT_PROXY.
...
    call method PROXY->GET_APPLICATION_PROPERTY
      exporting
        PROPERTY_NAME    = 'INTERNATIONAL'
        SUBPROPERTY_NAME = 'DECIMAL_SEPARATOR'
        NO_FLUSH         = NO_FLUSH
      importing
        RETCODE          = RETCODE
      changing
        RETVALUE         = DECIMAL_SIGN_EXT.

nicky555

вот это в тему, респект

все остальное - частный случай и, далее, off-topic...

trop

менее лаконичный вариант

Code:

  data:
    sdecimal type string,
    smondecimal type string.

  call method cl_gui_frontend_services=>registry_get_value
    exporting
      root = cl_gui_frontend_services=>hkey_current_user
      key = 'Control Panel\International'
      value = 'sDecimal'
    importing
      reg_value = sdecimal
    exceptions
      get_regvalue_failed = 1
      cntl_error = 2
      error_no_gui = 3
      not_supported_by_gui = 4
      others = 5.
  if sy-subrc ne 0.
    " panic
  endif.

  call method cl_gui_frontend_services=>registry_get_value
    exporting
      root = cl_gui_frontend_services=>hkey_current_user
      key = 'Control Panel\International'
      value = 'sMonDecimalSep'
    importing
      reg_value = smondecimal
    exceptions
      get_regvalue_failed = 1
      cntl_error = 2
      error_no_gui = 3
      not_supported_by_gui = 4
      others = 5.
  if sy-subrc ne 0.
    " panic
"    smondecimal = sdecimal.
  endif.

  cl_gui_cfw=>flush( ).
  write: sdecimal, smondecimal.

nicky555

Как я уже сказал, считывание реестра не даст общей картины.
Вряд ли будет работать в диапазоне рабочей системы Windows95 - Windows Vista + Excel95 - Excel ...

trop

а откуда по вашему doi proxy берет значения? )
база COM в реестре хранится, полагаю, считывание реестра быстрее
чем использование proxy объекта, но это надо проверить

Parazit

Для совместимости Excel разных версий я делал так:

Code:

FORM GET_EXCEL_DECIMAL_SEPARATOR
  USING RESULT.

  DATA:
    APP TYPE OLE2_OBJECT,
    USESYSTEMSEPARATORS(10).

  CREATE OBJECT APP 'Excel.Application'.
  IF SY-SUBRC = 0.
    GET PROPERTY OF APP
      'UseSystemSeparators' = USESYSTEMSEPARATORS.
    CALL FUNCTION 'FLUSH'.

    IF SY-SUBRC <> 0 OR
     ( SY-SUBRC = 0 AND USESYSTEMSEPARATORS <> 0 ).

      PERFORM GET_SYSTEM_DECIMAL_SEPARATOR
        USING RESULT.
    ELSE.
      GET PROPERTY OF APP
        'DecimalSeparator' = RESULT.
      CALL FUNCTION 'FLUSH'.
    ENDIF.

    FREE OBJECT APP.
    CALL FUNCTION 'FLUSH'.
  ENDIF.
ENDFORM.

FORM GET_SYSTEM_DECIMAL_SEPARATOR
  USING RESULT.

  DATA:
    HKEY_CURRENT_USER TYPE I VALUE 1.

  CALL FUNCTION 'GUI_GET_REGVALUE'
       EXPORTING
            ROOT           = HKEY_CURRENT_USER
            KEY            = 'Control Panel\International'
            VALUE_NAME     = 'sDecimal'
       CHANGING
            STRING         = RESULT
       EXCEPTIONS
            REGISTRY_ERROR = 1.
ENDFORM.

Правила форума

Вопрос на засыпку :)))

Кто сейчас на конференции