REPORT zimg_search NO STANDARD PAGE HEADING.

TABLES: sscrfields.
DATA: tcode TYPE tstc-tcode
    , cobject TYPE objh-objectname
    .
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT (20) tcodenm FOR FIELD s_tcode.
SELECT-OPTIONS: s_tcode FOR tcode.
SELECTION-SCREEN END OF LINE.

SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT (20) cobjnm FOR FIELD s_cobj.
SELECT-OPTIONS: s_cobj FOR cobject.
SELECTION-SCREEN END OF LINE.

SELECTION-SCREEN SKIP.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN PUSHBUTTON 4(10) find USER-COMMAND find.
SELECTION-SCREEN PUSHBUTTON 22(13) edit USER-COMMAND edit.
SELECTION-SCREEN END OF LINE.

TABLES: cus_actobj, cus_imgach.

TYPES: BEGIN OF t_cus_imgac
        , activity TYPE cus_imgact-activity
        , text TYPE cus_imgact-text
        , tcode TYPE tstc-tcode
     , END OF t_cus_imgac
.
TYPES: BEGIN OF t_act_id
        , act_id TYPE cus_act
        , tcode TYPE tstc-tcode
     , END OF t_act_id
.
DATA: it_act_id TYPE TABLE OF t_act_id
    , it_cus_imgac TYPE TABLE OF t_cus_imgac
    , i TYPE i
.
FIELD-SYMBOLS: <act_id> TYPE t_act_id
    , <img_ac> TYPE t_cus_imgac
.

INITIALIZATION.
  find = '@13@ Find'.
  edit = '@3Q@ Maintain'.
  tcodenm = 'Код транзакции'.
  cobjnm  = 'Имя объекта'.

AT SELECTION-SCREEN OUTPUT.

AT SELECTION-SCREEN.
  REFRESH it_act_id.

  IF s_tcode[] IS INITIAL AND s_cobj[] IS INITIAL.
    MESSAGE 'Введите код транзакции и/или имя объекта' TYPE 'E'.
  ENDIF.


  " Поиск по названию таблицы/ракурса
  SELECT act_id tcode
     INTO TABLE it_act_id
     FROM cus_actobj
     WHERE tcode IN s_tcode
       AND objectname IN s_cobj.

  LOOP AT it_act_id ASSIGNING <act_id>.
    SELECT cus_imgach~activity cus_imgact~text
       APPENDING TABLE it_cus_imgac
       FROM cus_imgach
       LEFT OUTER JOIN cus_imgact
          ON  cus_imgach~activity = cus_imgact~activity
          AND cus_imgact~spras = sy-langu
       WHERE c_activity = <act_id>-act_id.
  ENDLOOP.

  " Поиск по коду транзакции
  SELECT cus_imgach~activity cus_imgact~text
     APPENDING TABLE it_cus_imgac
     FROM cus_imgach
     LEFT OUTER JOIN cus_imgact
        ON  cus_imgach~activity = cus_imgact~activity
        AND cus_imgact~spras = sy-langu
     WHERE tcode IN s_tcode.

  IF it_cus_imgac[] IS INITIAL.
    MESSAGE 'Код транзакции и/или объект не найдены' TYPE 'E'.
  ENDIF.


  SORT it_cus_imgac.
  DELETE ADJACENT DUPLICATES FROM it_cus_imgac.
  DESCRIBE TABLE it_cus_imgac LINES i.

  IF i = 0.
    MESSAGE e000(su) WITH 'Объект' cus_actobj-act_id 'не привязан к IMG'.
  ELSEIF i > 1.
    CALL FUNCTION 'SAPGUI_SET_FUNCTIONCODE'
      EXPORTING
        functioncode = 'ONLI'.
  ELSE.
    READ TABLE it_cus_imgac ASSIGNING <img_ac> INDEX 1.
    PERFORM show_dialog.
  ENDIF.


START-OF-SELECTION.
  LOOP AT it_cus_imgac ASSIGNING <img_ac>.
    WRITE: / <img_ac>-activity INTENSIFIED off, <img_ac>-text.
  ENDLOOP.

AT LINE-SELECTION.
  READ TABLE it_cus_imgac ASSIGNING <img_ac> INDEX sy-lilli.
  PERFORM show_dialog.

*&---------------------------------------------------------------------*
*&      Form  show_dialog
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM show_dialog.
  CASE sscrfields-ucomm.
    WHEN 'FIND'  OR ''.
      CALL FUNCTION 'S_CUS_IMG_ACTIVITY_XREF'
        EXPORTING
          img_activity = <img_ac>-activity.
    WHEN 'EDIT'.
      CALL FUNCTION 'S_CUS_IMG_ACTIVITY_MAINTAIN'
        EXPORTING
          i_display    = 'X'
        CHANGING
          img_activity = <img_ac>-activity.
  ENDCASE.

ENDFORM.                    "show_dialog