TRANSLATE струкруту TO UPPER CASE (ecc 6.0)

b_e_s

Code:

TRANSLATE s_tab TO UPPER CASE.

Где s_tab - структура
Это проходило в 4.7 но не проходит в ecc6.0
Может кто знает как это сделать НЕ field-by-field ?

Marmelade

b_e_s написал(а):

Code:

TRANSLATE s_tab TO UPPER CASE.

Где s_tab - структура
Это проходило в 4.7 но не проходит в ecc6.0
Может кто знает как это сделать НЕ field-by-field ?

извращенный вариант:

Code:

field-symbols <fs> type any.
do.
 assign component sy-index of structure s_tab to <fs>.
 if sy-subrc eq 0.
   translate <fs> to upper case.
 else.
   exit.
 endif.
enddo.

b_e_s

Marmelade написал(а):

извращенный вариант:

.. и на том спасибо =)

Galka

может у вас еще и юникод-система? вообще тогда нельзя так грубо со структурами.

WhiteScorpio

Надо не забывать, что в Unicode буквы в 2-ух, а цифры (type p) в 1-ом. В честь этого 5.0-6.0 и не позволяет так грубо.)

vga

Marmelade написал(а):

извращенный вариант:

Code:

DATA: num TYPE P.
num = '987654321'.
write: / num.
translate num to upper case.
write: / num.

Цитата:

* Система 4.7

987.654.321
985.654.321

В неюникодных системах TRANSLATE до символа 'Z' работает наложением битовой маски (обнуление 5 бита в символе), после - по трансляционным таблицам. В юникодной системе, судя по выдаче, используется похожий алгоритм.

Mike1

Marmelade написал(а):

извращенный вариант:

Без дампов в юникод системе будет работать:

Code:

field-symbols <FS> type any.
data S_TAB type SYST.
data: DR  type ref to CL_ABAP_STRUCTDESCR,
       WA type ABAP_COMPDESCR.
S_TAB = SYST.
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_NAME( 'SYST' ).
do.
  assign component SY-INDEX of structure S_TAB to <FS>.
  if SY-SUBRC eq 0.
    read table DR->COMPONENTS index SY-INDEX into WA.
    if WA-TYPE_KIND = 'C'.
      translate <FS> to upper case.
    endif.
  else.
    exit.
  endif.
enddo.

b_e_s

Galka написала:

может у вас еще и юникод-система? вообще тогда нельзя так грубо со структурами.

Да система unicod, и преобразование поле-за-полем можно делать только анализируя тип. т.к. на I - система дампится. Это всё хорошо, когда структура из словаря. а если нет, то как получить типы полей?
Нада теперь, конешно, создать такой ФМ чтобы структуру перефодил в кейсы разные.

b_e_s

Mike1 написал:

Code:

field-symbols <FS> type any.
data S_TAB type SYST.
data: DR  type ref to CL_ABAP_STRUCTDESCR,
       WA type ABAP_COMPDESCR.
S_TAB = SYST.
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_NAME( 'SYST' ).
do.
  assign component SY-INDEX of structure S_TAB to <FS>.
  if SY-SUBRC eq 0.
    read table DR->COMPONENTS index SY-INDEX into WA.
    if WA-TYPE_KIND = 'C'.
      translate <FS> to upper case.
    endif.
  else.
    exit.
  endif.
enddo.

Отличный вариант, спасибо.

Но можно ли как-то сделать чтобы структуры объявленные в коде тоже как-то обработать?

vga

в чем проблема?
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_DATA( S_TAB ).
Determining the Attributes of Data Objects

b_e_s

vga написал(а):

в чем проблема?
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_DATA( S_TAB ).

дампит =( с S_TAB с кавычками и без.

Code:

DATA: BEGIN OF s_tab
,           fio(10)         TYPE c
,           count           TYPE i
,           rus(10)         TYPE c.
DATA  END   OF s_tab.

s_tab-fio   = 'test'.
s_tab-count = 101.
s_tab-rus   = 'однако!'.

FIELD-SYMBOLS <fs> TYPE ANY.
DATA: dr TYPE REF TO cl_abap_structdescr,
      wa TYPE abap_compdescr.
dr ?= cl_abap_typedescr=>describe_by_name( S_TAB ).
DO.
  ASSIGN COMPONENT sy-index OF STRUCTURE s_tab TO <fs>.
  IF sy-subrc EQ 0.
    READ TABLE dr->components INDEX sy-index INTO wa.
    IF wa-type_kind = 'C'.
      TRANSLATE <fs> TO UPPER CASE.
    ENDIF.
  ELSE.
    EXIT.
  ENDIF.
ENDDO.

BREAK-POINT.

vga

Вы невнимательны.
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_DATA( S_TAB ).

b_e_s

vga написал(а):

Вы невнимательны.
DR ?= CL_ABAP_TYPEDESCR=>DESCRIBE_BY_DATA( S_TAB ).

Огромное спасибо!

Правила форума

TRANSLATE струкруту TO UPPER CASE (ecc 6.0)

Кто сейчас на конференции