F4IF_INT_TABLE_VALUE_REQUEST - неправильное отображение содержимого таблицы значений

Danila

Добрый день, Коллеги.

В процессе использования функционального модуля F4IF_INT_TABLE_VALUE_REQUEST столкнулся со следующей проблеммой.
В качестве значение, по которым должен осуществляться поиск использую внутреннюю таблицу: IT_TAB, имеющую структуру, состоящую из 2-х полей: FIELD1 и FIELD2. Эти же поля указываю в таблице IT_FIELDS, которую передаю в ФМ в качестве параметра FIELD_TAB.
Таблица IT_TAB сщдержит 3 записи:
FIELD1 | FIELD2
TEXT11 | TEXT12
TEXT21 | TEXT22
TEXT31 | TEXT32

Вот код:

Code:

     
* Заполнение каталога полей для вывода средства поиска:

      CLEAR wa_fields.
      wa_fields-tabname       = 'IT_TAB'.
      wa_fields-fieldname     = 'FIELD1'.
      wa_fields-leng = 10.
      wa_fields-intlen = 10.
      wa_fields-outputlen     = 10.
      APPEND wa_fields TO it_fields.

      CLEAR wa_fields.
      wa_fields-tabname       = 'IT_TAB'.
      wa_fields-fieldname     = 'FIELD2'.
      wa_fields-leng = 10.
      wa_fields-intlen = 10.
      wa_fields-outputlen     = 10.
      APPEND wa_fields TO it_fields.

* Вывод средства поиска:

      CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
        EXPORTING
          RETFIELD               = 'FIELD1'
          DYNPPROG               = sy-repid
          DYNPNR                 = sy-dynnr
        TABLES
          VALUE_TAB              = IT_TAB
          FIELD_TAB              = IT_FIELDS
          RETURN_TAB             = IT_TAB_RETURN
       EXCEPTIONS
          PARAMETER_ERROR        = 1
          NO_VALUES_FOUND        = 2
          OTHERS                 = 3
                .
      IF SY-SUBRC <> 0.
        MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.

после запуска средство поиска отображается неправильно. а именно:

FIELD1 | FIELD2
TEXT11 | TEXT12 TEXT22
TEXT31 |

И всё.
Пробовал "играть" с параметрами длины вывода, но положительного результата достигнуть не удалось...
Также пробовал передавать на вход в качестве таблицы IT_TAB строковую таблицу, содержащую в каждой записи конкатенацию FIELD1+FIELD2, т. е. TEXT11TEXT12, например, для 1-й записи, но это также не сказалось на результате.

Подскажите, пожалуйста, как можно решить данную проблемму, или же какой аналогичный ФМ можно использовать для данной задачи.

Заранее благодарен!

Удав

Закомментируйте параметр FIELD_TAB, параметру VALUE_ORG присвойте 'S'

Danila

Удав написал(а):

Закомментируйте параметр FIELD_TAB.

В этом случае выдаётся сообщение "Значения не найдены"

Удав

Вот рабочий код:

Code:

  DATA: return_tab TYPE TABLE OF ddshretval WITH HEADER LINE
      , BEGIN OF value_tab OCCURS 0
      ,   bukrs LIKE anla-bukrs
      ,   invnr LIKE anla-invnr
      ,   txt50 LIKE anla-txt50
      , END   OF value_tab.
  FIELD-SYMBOLS: <fs> TYPE ANY.
  SELECT bukrs invnr txt50
    FROM anla
    APPENDING CORRESPONDING FIELDS OF TABLE value_tab
    WHERE bukrs = p_bukrs.
  SORT value_tab BY invnr txt50.
  DELETE value_tab WHERE invnr IS INITIAL.
  DELETE ADJACENT DUPLICATES FROM value_tab COMPARING invnr.


  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
      retfield               = 'INVNR'
      dynpprog    = sy-repid
      dynpnr      = sy-dynnr
      value_org   = 'S'
    TABLES
      value_tab              = value_tab[]
*     FIELD_TAB               = field_tab[]
      return_tab             = return_tab[]
   EXCEPTIONS
     parameter_error        = 1
     no_values_found        = 2
     OTHERS                 = 3.

Пономарев Артем

Ну тогда уж и мой рабочий, без комментирования

Code:

DATA: lt_matnr_hu  TYPE v_matnr_hu_t,
        ls_fieldtab  TYPE dfies,
        lt_fieldtab  TYPE TABLE OF dfies,
        ls_return    TYPE bapiret2.
  
  ls_fieldtab-tabname   = 'V_MATNR_HU'.
  ls_fieldtab-fieldname = 'MATNR'. APPEND ls_fieldtab TO lt_fieldtab.
  ls_fieldtab-fieldname = 'MAKTX'. APPEND ls_fieldtab TO lt_fieldtab.
  ls_fieldtab-fieldname = 'VHART'. APPEND ls_fieldtab TO lt_fieldtab.
  ls_fieldtab-fieldname = 'MAGRV'. APPEND ls_fieldtab TO lt_fieldtab.
  ls_fieldtab-fieldname = 'MEINS'. APPEND ls_fieldtab TO lt_fieldtab.

  CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
    EXPORTING
      retfield     = 'MATNR'
      window_title = text-001
      value_org    = 'S'
    TABLES
      value_tab    = lt_matnr_hu
      field_tab    = lt_fieldtab
      return_tab   = lt_returne
    EXCEPTIONS
      OTHERS       = 99.

Удав

Пономарев Артем написал:

Ну тогда уж и мой рабочий, без комментирования

Если не указывать FIELD_TAB, то ФМ автоматически определяет структуру передаваемой таблицы

Danila

Всем спасибо!
Фича оказалась в параметре VALUE_ORG = 'S'.

При таком вызове каталог полей действительно не нужен!
Всем выражаю благодарность за помощь и внимание к проблемме!

Пономарев Артем

У меня там одно поле лишнее, в табличке. Мандант, которое

Я к тому что причина неправильной работы не в указании FIELD_TAB.
Но вот понять с ходу не могу, что у автора не так.

UPD: Теперь понял. Автор признался сам

Правила форума

F4IF_INT_TABLE_VALUE_REQUEST - неправильное отображение содержимого таблицы значений

Кто сейчас на конференции