HR_INFOTYPE_OPERATION падает в дамп с ошибкой ASSIGN_BASE_TOO_SHORT

Daemon

Доброе время суток.

Прошу помощи по такому вопросу - при занесении данных инфотипа (в данном случае данные берутся из другого mandt) в функции HR_INFOTYPE_OPERATION вылетаю в дамп с ошибкой ASSIGN_BASE_TOO_SHORT.

Ошибка происходит во время выполнения команды

ASSIGN record TO <record> CASTING TYPE (tabname). "XDP UniCode

Code:

DATA: wa TYPE pa0006,
      endda TYPE sy-datum,
      begda TYPE sy-datum,
      ls_ret    TYPE bapireturn1,
      wa_ret  LIKE bapipakey.

begda = sy-datum.
endda = sy-datum + 1.

SELECT *
   FROM pa0006 AS p1
   CLIENT SPECIFIED
   INTO wa
   WHERE p1~mandt = '050'
     AND p1~pernr = '66'.

  WRITE: / wa-pernr, wa-subty.

  CALL FUNCTION 'HR_INFOTYPE_OPERATION'
    EXPORTING
      infty                  = '0006'
      number                 = wa-pernr
*     subtype                = wa-subty
*      OBJECTID               =
*      LOCKINDICATOR          =
     validityend            = endda
     validitybegin          = begda
*     recordnumber           = wa-seqnr
      record                 = wa
      operation              = 'INS'
*      TCLAS                  = 'A'
     dialog_mode            = '0'
     nocommit               = 'X'
*      VIEW_IDENTIFIER        =
*      SECONDARY_RECORD       =
   IMPORTING
     return                 = ls_ret
     key                    = wa_ret             .

  IF ls_ret-type NE space AND
     'AXE' CS ls_ret-type. 
    WRITE: / 'infotype addition failed'.
    ROLLBACK WORK.
  ELSE.
    COMMIT WORK.
  ENDIF.
ENDSELECT.

Ломаю голову - в чем может быть проблема?

RoustR

Для строки ASSIGN record TO <record> CASTING TYPE (tabname) это ошибка означает, что длина структуры record не совпадает с длиной структуры, который определяется типом tabname. Скорее всего тип перепутан.

Если немного посмотреть код, то можно увидеть, что tabname получается из поля I777D-PPNNN

Code:

TABNAME = I777D-PPNNN

В T777D-PPNNN для ИТ0006 лежит значение 'P0006'. Это значит в качестве record в HR_INFOTYPE_OPERATION нужно передать структуру типа p0006, а у тебя передается pa0006. Эти типы данных не совпадают.

Попробуй добавить такой код

Code:

DATA w type p0006.

...
clear w.
MOVE-CORRESPONDING wa TO w.

CALL FUNCTION 'HR_INFOTYPE_OPERATION'
    EXPORTING
...
      record                 = w
...

Daemon

Спасибо огромное. Помогло.

Правила форума

HR_INFOTYPE_OPERATION падает в дамп с ошибкой ASSIGN_BASE_TOO_SHORT

Кто сейчас на конференции