ФМ для генерации т-ц.

msi

Ищу системный ФМ для генерации т-ц.
На вход - структура.
На выходе - таблица (этой структуры) с заголовком например.
Помню было что то подобное с названием что-то *CREATE*DYNAMIC*TABLE*... в САПе не нашел что-то.... Поиск по форуму глючит. Поможите кто чем... =)

Helper

на странице viewtopic.php?f=13&t=53411

CALL METHOD cl_alv_table_create=>create_dynamic_table
EXPORTING
it_fieldcatalog = lt_fldcat
IMPORTING
ep_table = ex_dyntab
EXCEPTIONS
generate_subpool_dir_full = 1
OTHERS = 2.

msi

Точно! Метод! Спасибо добрый человек.

raaleksandr

А вот еще такой вариант, лишенный "ошибки 36"

И не требующий fieldcatalog-а

Code:

  " Здесь разные варианты объявления структуры - можно dictionary, можно свои

  "DATA: st TYPE usr21.

  DATA: BEGIN OF st,
          field1    TYPE char10,
          field2    TYPE text50,
        END OF st.

  DATA: lr_data TYPE REF TO data.

  FIELD-SYMBOLS: <lt>    TYPE any table.

  CREATE DATA lr_data LIKE TABLE OF st.
  ASSIGN lr_data->* TO <lt>.

  BREAK-POINT.  " Здесь видим, что таблица создалась нужного типа в <lt>

imp

И мои 5 копеек.
В свежих релизах (7.0+) можно использовать RTTI

Code:

TYPE-POOLS: abap.
 
DATA:
  lr_structdescr    TYPE REF TO cl_abap_structdescr,
  lr_tabledescr     TYPE REF TO cl_abap_tabledescr,
  lr_datadescr      TYPE REF TO cl_abap_datadescr,
  lt_components     TYPE abap_component_tab,
  ls_component      TYPE LINE OF abap_component_tab,
  lr_wa             TYPE REF TO data,
  lr_tab            TYPE REF TO data.
 
DATA: lv_index_num(3) TYPE n.
DATA: lv_index_char(3) TYPE c.
 
FIELD-SYMBOLS: <fs_wa> TYPE ANY.
FIELD-SYMBOLS: <fs_tab> TYPE table.
 
START-OF-SELECTION.
 
  DO 20 TIMES.
    lv_index_num = sy-index.
    lv_index_char = lv_index_num.
    CONCATENATE 'value' lv_index_char INTO ls_component-name.
    ls_component-type ?= cl_abap_elemdescr=>get_c( p_length = 10 ).
    INSERT ls_component INTO TABLE lt_components.
  ENDDO.
 
* get structure descriptor -> lr_STRUCTDESCR
  lr_structdescr ?= cl_abap_structdescr=>create( lt_components ).
 
* create work area of structure lr_STRUCTDESCR -> lr_WA
  CREATE DATA lr_wa TYPE HANDLE lr_structdescr.
  ASSIGN lr_wa->* TO <fs_wa>.
 
  lr_datadescr ?= lr_structdescr.
  lr_tabledescr ?= cl_abap_tabledescr=>create( lr_datadescr ).
 
* Create dynmaic internal table
  CREATE DATA lr_tab TYPE HANDLE lr_tabledescr.
  ASSIGN lr_tab->* TO <fs_tab>.

Взято тут: http://forums.sdn.sap.com/thread.jspa?threadID=1615758

Правила форума

ФМ для генерации т-ц.

Кто сейчас на конференции