Открыть документ из SOOD во внешнем приложении

Luta347

Необходимо открыть документы во внешнем приложении (в моем случае - это файлы txt) из таблички SOOD.. может быть есть ФМ какой-нибудь? перерыл множество форумов, но так и не нашел пока информации, как можно это реализовать..

weise

Общий подход к таком случае - выгрузить файл на компьютер пользователя и вручную запустить нужное приложение, передав ему путь к выгруженному файлу (при помощи, например, WS_EXECUTE или GUI_EXEC).

Luta347

А например открывать документ во внешнем приложении по клику в алв таблице без его выгрузки на компьютер.. возможно ли это реализовать?

broker.chelny

Ну тогда выгружайте на сервер приложений, расшарьте папку и передавайте в приложение сетевой путь.

weise

Чтобы внешнее (т.е. локальное на компьютере пользователя) приложение открыло документ (файл) оно должно его как-то получить. Варианта 2: либо скачать файл, либо запустить приложение и скормить ему каким-либо образом поток байт нашего файла. Второе умеют немногие приложения. В частности можно передать ссылку (http или smb, не суть). Но это же сложнее.

Luta347

По ключу состоящему из 3х полей в таблице sood я нашел 2 записи в таблице sofm, после этого открыл ракурс sofm/sood и оказалось, что это и есть 2 файла прикрепленных к документу..У каждого из файлов есть свой ключ тоже состоящий из 3х полей в таблице sofm.
Теперь имея 2 ключа(один из sood, второй из sofm), я выгрузил файлы и открыл во внешнем приложении с помощью фм SO_DOCUMENTS_MANAGER

выглядит это примерно так:

Code:

data ls_v_sofc type v_sofc.
  select single foltp folyr folno doctp docyr docno from v_sofc into corresponding fields of ls_v_sofc
    where foltp = objtp
      and folyr = objyr
      and folno = objno.

  data lt_docs type table of sood4.
  data ls_docs like line of lt_docs.
  ls_docs-objtp = ls_v_sofc-foltp.
  ls_docs-objyr = ls_v_sofc-folyr.
  ls_docs-objno = ls_v_sofc-folno.
  ls_docs-atttp = ls_v_sofc-doctp.
  ls_docs-attyr = ls_v_sofc-docyr.
  ls_docs-attno = ls_v_sofc-docno.
  append ls_docs to lt_docs.
  call function 'SO_DOCUMENTS_MANAGER'
    exporting
      activity  = 'DISP'
    tables
      documents = lt_docs.

p.s. Может кому то поможет :wink:

Сергей Королев

С помощью класса cl_gui_html_viewer можно показать практически любой контент из SOOD, главное озаботиться хранением mime-типа.
Фрагмент работающего кода:

Code:

  DATA: lt_solix TYPE TABLE OF solix,
        ls_document_data TYPE sofolenti1,

        lt_data TYPE srt_abuf_transport_tab,
        l_size TYPE i,

        l_url TYPE text1024.

  CALL FUNCTION 'SO_DOCUMENT_READ_API1'
    EXPORTING
      document_id                = i_doc_id
    IMPORTING
      document_data              = ls_document_data
    TABLES
      contents_hex               = lt_solix
    EXCEPTIONS
      document_id_not_exist      = 1
      operation_no_authorization = 2
      x_error                    = 3
      OTHERS                     = 4.

  IF sy-subrc <> 0.
  ENDIF.

  DATA: content_viewer TYPE REF TO cl_gui_html_viewer.

  CREATE OBJECT content_viewer
    EXPORTING
      parent = cl_gui_container=>screen0.
*      parent = cl_gui_container=>desktop.

  IF content_viewer IS BOUND.
    l_size = ls_document_data-doc_size.
    content_viewer->load_data(
      EXPORTING
        type         = i_mime_type                          "#EC NOTEXT
        subtype      = space
        size         = l_size
      IMPORTING
        assigned_url = l_url
      CHANGING
        data_table   = lt_solix
      EXCEPTIONS
        OTHERS       = 1
    ).

    IF sy-subrc = 0 AND NOT l_url IS INITIAL.
      content_viewer->show_url(
        EXPORTING
          url = l_url
          frame    = space
          in_place = space
        EXCEPTIONS
          OTHERS   = 0
      ).
    ENDIF.

    CALL METHOD content_viewer->set_visible
      EXPORTING
        visible = cl_gui_control=>visible_false.

    CALL METHOD content_viewer->free.
  ENDIF.

Правила форума

Открыть документ из SOOD во внешнем приложении

Кто сейчас на конференции