Монитор с периодическим обновлением

Clarus

Добрый день ! Хочется сделать отчет на ALV Grid, который бы после первичного показа обновлялся бы автоматически (без нажатия кнопок оператором), с определенной периодичностью. Кому приходилось сталкиваться, поделитесь идеями, pls.

Дмитрий

Для ALV Grid не пробовал, а для листингового отчета работает "на ура!". Больших проблем не должно возникнуть.
Посмотри help по CALL FUNCTION ..STARTING NEW TASK.
Нужно асинхронно в новой сессии запустить ф.м., например, RFC_PING_AND_WAIT. В нем есть параметр - кол-во секунд через которое он закончит выполняться - это и будет время обновления. В ON END OF TASK указываешь подпрограмму, которая вызовет обновление грида и затем перезапустит заново асинхронный процесс. :wink:

Вообще "классическое" решение - кнопка "обновления", которую нажимает пользователь, когда ему нужно.

Clarus

Большое спасибо, попробую.

Гость1

У класса CL_GUI_ALV_GRID есть метод SET_AUTOREDRAW, можно попробовать

Stepan

Code:

REPORT z_alv_auto_refresh.
*>*********************************************************************
* This report displays User's info (SM04) using the FM :              *
* REUSE_ALV_LIST_DISPLAY                                              *
* The list is auto-refreshed (refresh time : 5 seconds)               *
*---------------------------------------------------------------------*

TYPE-POOLS: slis.                      " ALV Global Types

DATA :
  gt_user LIKE uinfo OCCURS 0 WITH HEADER LINE. " User info in SM04

*---------------------------------------------------------------------*
START-OF-SELECTION.

  PERFORM f_read_data.

  PERFORM f_display_data.

*---------------------------------------------------------------------*
*       Form  F_LIRE_DATA
*---------------------------------------------------------------------*
FORM f_read_data.

  REFRESH gt_user.

* Get User's info
  CALL FUNCTION 'THUSRINFO'
       TABLES
            usr_tabl = gt_user.

* Wait in a task
  PERFORM f_call_rfc_wait.

ENDFORM.                               " F_READ_DATA
*---------------------------------------------------------------------*
*      Form  F_DISPLAY_DATA
*---------------------------------------------------------------------*
FORM f_display_data.

  DEFINE m_sort.
    add 1 to ls_sort-spos.
    ls_sort-fieldname = &1.
    append ls_sort to lt_sort.
  END-OF-DEFINITION.

  DEFINE m_event_exit.
    clear ls_event_exit.
    ls_event_exit-ucomm = &1.
    ls_event_exit-after = 'X'.
    append ls_event_exit to lt_event_exit.
  END-OF-DEFINITION.

  DATA :
    ls_layout     TYPE slis_layout_alv,
    lt_sort       TYPE slis_t_sortinfo_alv,
    ls_sort       TYPE slis_sortinfo_alv,
    lt_event_exit TYPE slis_t_event_exit,
    ls_event_exit TYPE slis_event_exit.

* Build Sort Table
  m_sort 'ZEIT'.

* Build Event Exit Table
  m_event_exit '&NTE'.                 " Refresh

  ls_layout-zebra = 'X'.
  ls_layout-colwidth_optimize = 'X'.
  SET USER-COMMAND '&OPT'.         " Optimize columns width

  CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
       EXPORTING
            i_callback_program      = sy-cprog
            i_callback_user_command = 'USER_COMMAND'
            is_layout               = ls_layout
            i_structure_name        = 'UINFO'
            it_sort                 = lt_sort
            it_event_exit           = lt_event_exit
       TABLES
            t_outtab                = gt_user.

ENDFORM.                               " F_DISPLAY_DATA
*---------------------------------------------------------------------*
*       FORM USER_COMMAND                                             *
*---------------------------------------------------------------------*
FORM user_command USING i_ucomm     TYPE syucomm
                        is_selfield TYPE slis_selfield.     "#EC CALLED

  CASE i_ucomm.
    WHEN '&NTE'.
      PERFORM f_read_data.
      is_selfield-refresh = 'X'.
      SET USER-COMMAND '&OPT'.         " Optimize columns width
  ENDCASE.

ENDFORM.                               " USER_COMMAND
*---------------------------------------------------------------------*
*      Form  F_CALL_RFC_WAIT
*---------------------------------------------------------------------*
FORM f_call_rfc_wait.

  DATA lv_mssg(80).                                         "#EC NEEDED

* Wait in a task
  CALL FUNCTION 'RFC_PING_AND_WAIT' STARTING NEW TASK '001'
    PERFORMING f_task_end ON END OF TASK
    EXPORTING
      seconds               = 5        " Refresh time
      busy_waiting          = space
    EXCEPTIONS
      RESOURCE_FAILURE      = 1
      communication_failure = 2  MESSAGE lv_mssg
      system_failure        = 3  MESSAGE lv_mssg
      OTHERS                = 4.

ENDFORM.                               " F_CALL_RFC_WAIT
*---------------------------------------------------------------------*
*      Form  F_TASK_END
*---------------------------------------------------------------------*
FORM f_task_end USING u_taskname.

  DATA lv_mssg(80).                                         "#EC NEEDED

* Receiving task results
  RECEIVE RESULTS FROM FUNCTION 'RFC_PING_AND_WAIT'
    EXCEPTIONS
      RESOURCE_FAILURE      = 1
      communication_failure = 2  MESSAGE lv_mssg
      system_failure        = 3  MESSAGE lv_mssg
      OTHERS                = 4.

  CHECK sy-subrc EQ 0.
  SET USER-COMMAND '&NTE'.             " Refresh

ENDFORM.                               " F_TASK_END
*************** END OF PROGRAM Z_ALV_AUTO_REFRESH *********************

Clarus

Ух, мощно

! Stepan, большое спасибо !

111

ИМХО, все делается несколько проще.
Вроде бы должен ФМ таймера (к сожалению, прямо сейчас не смог вспомнить). По событию просто вызывается нужный
SET USER-COMMAND <нужный фкод>.

Mahouni

можа кому будет интересно, Степанов пример и другое есть на сайте http://www.sap-basis-abap.com/abap/auto ... v-list.htm

Ich Will

Соррии за оффтопик...
А может сделать свой сборник рецептов ввиде отдельного топика CookBook, там складывать интересные , полезные, красивые решения
какой-нибудь проблеммы... ИМХО будет очень полезно...

Так же было бы супер завести FAQ со слылками для начинающих и примерами для самых маленьких

) итд....

Stepan

[url]
http://www.sapfans.com/forums/viewforum.php?f=31
[/url]

andj

Добрый день.

Основываясь на вышеописанном примере сделал отчет.

С функцией 'REUSE_ALV_LIST_DISPLAY' обновление работает замечательно, но стоит заменить функцию на 'REUSE_ALV_GRID_DISPLAY' отчет перестает автоматически обновляться .

Кто решал данную проблемку, поделитесь опытом.

vga

Проблема не решается. Callback функции не работают с rfc вызовами.

VGhost

andj написал(а):

Кто решал данную проблемку, поделитесь опытом.

Действительно, запустить автообновление ALV Grid с использованием rfc вызовов или класса CL_GUI_TIMER фактически невозможно. Но есть еще один способ.

Проблема может быть решена следующим образом.
1. Берем класс

cl_gui_html_viewer
2. В него загружаем например следующую страничку:

Code:

<HTML>
<HEAD><meta http-equiv="Content-Type" content="text/html; codepage=1251">
<TITLE>sample form</TITLE>
<script>
function fnTimer() {
window.setInterval( "FORM1.submit()", 5000);
}
</script>
</HEAD>
<body onload="fnTimer( );">
<form id=FORM1 method="POST" action="SAPEVENT:TIMEOUT"><input type="hidden" name="hd1" value="0">
</form>
</BODY>
</HTML>

3. Пишем обработчик событий для класса, и в методе on_sapevent выполняем процедуру обновления своего грида и всего чего угодно.

Code:

class lcl_sapevent_receiver definition.

  public section.
    methods  on_sapevent
                for event sapevent of cl_gui_html_viewer
                  importing
                    action frame getdata postdata query_table
            .

endclass.    

4. Наслаждаемся творением рук своих...

Более подробную документацию по использованию класса cl_gui_html_viewer можно посмотреть в документации.

Jelena

Ich Will написал:

Соррии за оффтопик...
А может сделать свой сборник рецептов ввиде отдельного топика CookBook, там складывать интересные , полезные, красивые решения
какой-нибудь проблеммы... ИМХО будет очень полезно...

Так же было бы супер завести FAQ со слылками для начинающих и примерами для самых маленьких

) итд....

IMHO сборник рецептов рискует быстро превратиться в бесконечное обсуждение рецептов, если только не сделать топик закрытым со входом "по приглашению".

А вот простейший FAQ, состоящий из ссылок, очень даже напрашивается. Только нужен доброволец, чтобы этот FAQ составить и потом поддерживать. Остальные могли бы вносить свой вклад, сообщая тов. добровольцу (по ЛС) ссылки на топики-кандидаты.

vga

за три года добровольцев не нашлось :roll:

Правила форума

Монитор с периодическим обновлением

Кто сейчас на конференции