field-symbols

zxcvbn

Добрый день.

вопрос в следующем, как в программе динамически тип field-symbols определять?

РМщик

CREATE DATA

РМщик

Code:

DATA: RDAT TYPE REF TO DATA.
FIELD-SYMBOLS: <P>.

CREATE DATA RDAT TYPE ('BKPF').
ASSIGN RDAT->* TO <P>.

zxcvbn

нет, к сожалению, эта конструкция не помогает, так как мне потом необходимо прямое обращение к полям FIELD-SYMBOLS.

РМщик

Если Вы хотите все определять динамически,
ИМХО только такой принципиальный вариант:

Code:

DATA: RDAT TYPE REF TO DATA,
      NPOLE(20).
FIELD-SYMBOLS: <P>,
               <BUKRS>,
               <BUTXT>.

CREATE DATA RDAT TYPE ('T001').
ASSIGN RDAT->* TO <P>.

IF SY-SUBRC = 0.
  SELECT  * FROM T001 INTO <P>.
    NPOLE = '<P>-BUKRS'.
    ASSIGN (NPOLE) TO <BUKRS>.
    NPOLE = '<P>-BUTXT'.
    ASSIGN (NPOLE) TO <BUTXT>.
    WRITE:/  <BUKRS>,
             <BUTXT>.
  ENDSELECT.
ENDIF.

.

но может есть другие...

РМщик

вот даже более наглядный пример:

Code:

CONSTANTS:
* Имя таблицы
           T(10) VALUE  'T001',
* Список полей
           P1(10) VALUE 'BUKRS',
           P2(10) VALUE 'BUTXT'.


DATA: RDAT TYPE REF TO DATA,
      NPOLE(20).
FIELD-SYMBOLS: <P>,
               <POLE1>,
               <POLE2>.

CREATE DATA RDAT TYPE (T).
ASSIGN RDAT->* TO <P>.

IF SY-SUBRC = 0.
  SELECT  * FROM (T) INTO <P>.
    CONCATENATE '<P>-' P1 INTO NPOLE .
    ASSIGN (NPOLE) TO <POLE1>.
    CONCATENATE '<P>-' P2 INTO NPOLE .
    ASSIGN (NPOLE) TO <POLE2>.
    WRITE:/  <POLE1>,
             <POLE2>.
  ENDSELECT.
ENDIF.

zxcvbn

сформулирую вопрос по другому: в подпрограмму передаются 2 структуры f_connect и f_device. У них есть одинаковые поля, которые необходимо присвоить l_data_generalx. Мне необходимо, чтобы тип field-symbols задавался динамически. Т.е., например, если f_connect непусто, то нужно к <fs> "приасайнить" f_connect. А если f_device непусто, то нужно к <fs> "приасайнить" f_device.

FORM change_bapi_for_isu USING f_connect TYPE t_connect
f_device TYPE t_device.

DATA: l_data_generalx LIKE bapi_itobx.

if not f_connect is initial.
field-symbols: <fs> type t_connect.
assign f_connect to <fs>.
elseif not f_device is initial.
*???????????????????
else.
exit.
endif.

l_data_general-descript = <fs>-pltxt.
l_data_general-maintplant = <fs>-swerk.

.................................

ENDFORM.

как бы это реализовать, посимпатичней?

РМщик

Code:

FORM CHANGE_BAPI_FOR_ISU USING
           F_CONNECT TYPE T_CONNECT
           F_DEVICE TYPE T_DEVICE.

  DATA: L_DATA_GENERAL LIKE BAPI_ITOB.

  FIELD-SYMBOLS: <FS>, <FP>.

  IF NOT F_CONNECT IS INITIAL.
    ASSIGN F_CONNECT TO <FS>.
  ELSEIF NOT F_DEVICE IS INITIAL.
    ASSIGN F_DEVICE TO <FS>.
  ELSE.
    EXIT.
  ENDIF.

  ASSIGN COMPONENT 'PLTXT' OF STRUCTURE <FS> TO <FP>.
  IF SY-SUBRC = 0.
    L_DATA_GENERAL-DESCRIPT = <FP>.
  ENDIF.
  ASSIGN COMPONENT 'SWERK' OF STRUCTURE <FS> TO <FP>.
  IF SY-SUBRC = 0.
    L_DATA_GENERAL-MAINTPLANT = <FP>.
  ENDIF.
  .................................
ENDFORM.                    "

zxcvbn

ну, в принципе вариант рабочий (я тоже об этом подумывал) но громоздко получается (полей много). Мне интересно есть что-то более изящное, никто не знает? может не через филд символы? например, нельзя ли как-то именно эту часть программы (декларация и присвоение филд символа), а не всю подпрограмму, динамически формировать через внутреннюю таблицу и что-нибудь типа GENERATE SUBROUTINE?

РМщик

zxcvbn написал(а):

ну, в принципе вариант рабочий (я тоже об этом подумывал)

Спасибо, шеф!

GENERATE SUBROUTINE - ИМХО лучше не использовать

vaseky

помогут макросы

vaseky

vaseky написал(а):

помогут макросы

DATA: l_data_generalx LIKE bapi_itobx.
define mac_set_val.
l_data_general-descript = &1-pltxt.
l_data_general-maintplant = &1-swerk.
end-of-definiton.

if not f_connect is initial.
mac_set_val f_connect.
elseif not f_device is initial.
mac_set_val f_device.
else.
exit.
endif.

zxcvbn

Да, макросы в данном случае - красивый и не громоздкий вариант.

К сожалению, проблема динамической типизации филд символов с дальнейшим использованием его полей так и осталась открытой.

но все равно, всем большое СПАСИБО!!!

РМщик

vaseky написал(а):

помогут макросы

да, этот вариант даже красивее

vaseky

zxcvbn написал(а):

К сожалению, проблема динамической типизации филд символов с дальнейшим использованием его полей так и осталась открытой.

почему открытой?
знаешь имя структуры и имя поля - дак и все делай ASSIGN, а если тебе надо в одну строку кода сделать, вынеси ASSIGN в FORM и все будет ОК:)
PERFORM set_val USING: ....1
....2.

или создай структуру с общими полями для f_connect и f_device и MOVE-CORRESPONDING хоть из филд символа, хоть сразу...

Правила форума

field-symbols

Кто сейчас на конференции