Метод insert_one_table (DOI)

влад

Добрый день всем. Может быть кто-нибудь сталкивался с вставкой таблиц в эксель или ворд. Для этого я использую DOI (без OLE). Вот мой код:

Code:

  DATA i_spreadsheet TYPE REF TO i_oi_spreadsheet.
  CALL METHOD i_document->get_spreadsheet_interface
    IMPORTING
      sheet_interface = i_spreadsheet.

  DATA gt_test TYPE TABLE OF string WITH HEADER LINE.
  gt_test = 'abcdefg'.
  APPEND gt_test.
  gt_test = 'hijklmn'.
  APPEND gt_test.

  CALL METHOD i_spreadsheet->insert_one_table
    EXPORTING
      data_table   = gt_test[]
      rangename    = 'table1'.

Проблема в том, что выпадаю в дамп всякий раз при выполнении метода insert_one_table (ошибка system failure). Причем то же наблюдается, если попытаться вставить таблицу в ворд через интерфейс i_oi_word_processor_document.

Почитал на help.sap.com - вроде бы никаких особенностей не нашел.

Lars

Попробуйте перед insert_one_table позвать

CALL METHOD i_spreadsheet->insert_range_dim.

влад

Спасибо за ответ.

Перед вызовом метода insert_one_table вставил этот код:

Code:

CALL METHOD i_spreadsheet->insert_range_dim
  EXPORTING
    name      = 'table1'
    left      = 1
    top       = 1
    rows      = 2
    columns   = 1.

Честно говоря, не совсем понял, что делает этот метод и какие должны быть параметры top и left. :oops:

Однако не помогло, теперь при выполнении метода insert_one_table выдает ошибку move_to_lit_not_allowed_nodata.

Lars

Честно говоря, не уверен, ...
Попробуйте в insert_one_table проставить галку на параметр wholetable = 'X'.

Galka

Объясняю

Code:

* -- field catalog for range
  CALL FUNCTION 'DP_GET_FIELDS_FROM_TABLE'
    TABLES
      data   = it_excel
      fields = fields_table.
  DESCRIBE TABLE fields_table LINES columns_number.

...

  DESCRIBE TABLE p_excel LINES rows_number.
* -- create an excel range for our data
  CALL METHOD spreadsheet->insert_range_dim
    EXPORTING
      name     = p_rname         " это имя должно совпадать с именем в insert_one_table
      top      = p_y                   " координата y левого верхнего угла
      left     = p_x                    " координата х левого верхнего угла
      rows     = rows_number   " количество строк в вашей таблице
      no_flush = 'X' 
      columns  = columns_number " столбцов в вашей таблице
    IMPORTING
      error    = error.

* -- transfer R/3 table data into excel range
  CALL METHOD spreadsheet->insert_one_table
    EXPORTING
      data_table   = p_excel[]
      rangename    = p_rname
      fields_table = fields_table
      no_flush     = 'X'
      wholetable   = 'X'
    IMPORTING
      error        = error.

влад

Спасибо за новые идеи. Правда я наврал... :oops:

ошибка возникает при обработке ФМ AC_FLUSH_CALL_INTERNAL, который вызывается автоматически после вызова insert_one_table с исключением System Failure. Пробовал снимать/ставить no_flush в параметрах - результат тот же. Импортируемый rcode возвращает 'call not flushed'. Что это может значить и как побороть?
Мой нынешний код:

Code:

  DATA gt_test TYPE TABLE OF string WITH HEADER LINE.
  gt_test = 'abcdefg'.
  APPEND gt_test.
  gt_test = 'hijklmn'.
  APPEND gt_test.

  DATA gt_ftab TYPE soi_fields_table WITH HEADER LINE.

  CALL METHOD i_spreadsheet->insert_range_dim
    EXPORTING
      NO_FLUSH  = 'X'
      name      = 'table1'
      left      = 1
      top       = 1
      rows      = 2
      columns   = 1.

  CALL FUNCTION 'DP_GET_FIELDS_FROM_TABLE'
    TABLES
      data   = gt_test[]
      fields = gt_ftab[].

  CALL METHOD i_spreadsheet->insert_one_table
    EXPORTING
      data_table   = gt_test[]
      fields_table = gt_ftab[]
      rangename    = 'table1'
      no_flush = 'X'
    IMPORTING
       retcode = rcode.

Обязательно ли использовать ФМ DP_GET_FIELDS_FROM_TABLE?

Lars

Code:

CALL FUNCTION 'DP_GET_FIELDS_FROM_TABLE' 
    TABLES 
      data   = gt_test[] 
      fields = gt_ftab[]. 

Обычно используеется чтобы посчитать кол-во столбцов и передать fields в insert_one_table.
И в этом случае его стоит вставить перед insert_range_dim.

Если опираетесь на словарную структуру - можно пользовать параметр ddic_name в том же методе.

И попробуйте, все таки, wholetable = 'X'
Может посмотрим весь код целиком с инициализациями и т.д. ?

влад

Спасибо за поддержку. Пытался я включить whole_table - тщетно.
Вот весь код моей незамысловатой программы:

Code:

REPORT zdoi_test.

DATA: i_control  TYPE REF TO i_oi_container_control.
DATA: i_document TYPE REF TO i_oi_document_proxy.
DATA: gr_container TYPE REF TO cl_gui_custom_container.

START-OF-SELECTION.
  PERFORM preparation.
  PERFORM excel_processing.

*&---------------------------------------------------------------------*
*&      Form  preparation
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM preparation.
* Creating the instance i_control
  CALL METHOD c_oi_container_control_creator=>get_container_control
    IMPORTING
      control = i_control.

* Initializing control
  CALL METHOD i_control->init_control
    EXPORTING
      r3_application_name = 'R/3 application'
      parent              = gr_container
      inplace_enabled     = ' '
      no_flush            = ' '.
ENDFORM.                    "preparation

*&---------------------------------------------------------------------*
*&      Form  excel_processing
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM excel_processing.

  CALL METHOD i_control->get_document_proxy
    EXPORTING
      document_type      = 'Excel.Sheet.8'
      register_container = 'X'
    IMPORTING
      document_proxy     = i_document.

  CALL METHOD i_document->create_document
    EXPORTING
      open_inplace = ' '.

  DATA i_spreadsheet TYPE REF TO i_oi_spreadsheet.
  CALL METHOD i_document->get_spreadsheet_interface
    IMPORTING
      sheet_interface = i_spreadsheet.


  DATA gt_test TYPE TABLE OF string WITH HEADER LINE.
  gt_test = 'abcdefg'.
  APPEND gt_test.
  gt_test = 'hijklmn'.
  APPEND gt_test.

  DATA gt_ftab TYPE soi_fields_table WITH HEADER LINE.

  CALL FUNCTION 'DP_GET_FIELDS_FROM_TABLE'
    TABLES
      data   = gt_test[]
      fields = gt_ftab[].

  CALL METHOD i_spreadsheet->insert_range_dim
    EXPORTING
      no_flush = 'X'
      name     = 'table1'
      left     = 1
      top      = 1
      rows     = 2
      columns  = 1.

  CALL METHOD i_spreadsheet->insert_one_table
    EXPORTING
      data_table   = gt_test[]
      fields_table = gt_ftab[]
      rangename    = 'table1'
      wholetable   = 'X'
      no_flush     = 'X'.

  WRITE 'Excel document has been created...'.

ENDFORM.                    "excel_processing

Lars

проблема. как мне кажется в объявлении таблички
gt_test

Сделайте её типа:

Code:

  DATA: begin of gt_test occurs 0,
         string(132),
        end of gt_test.

влад

Lars, спасибо огромное. Сказать по правде, не поверил своим глазам! :shock:

Действительно, все дело оказалось в объявлении тестовой таблички. А я даже и подумать не мог... Еще раз благодарю за помощь!

Galka

И как тут может нормальный человек догадаться?

влад

Да уж... самое плохое, что в документации ни слова...
Кстати, Galka, без ФМ DP_GET_FIELDS_FROM_TABLE, тоже не хотит работать, так что спасибо за совет

Lars

Думается мне, что передача типа string в excel идентична передаче array и variant, которые мы, к сожалению, передать не можем.

А DP_GET_FIELDS_FROM_TABLE работает нормально. Он вернул тип 'g' - видимо generic. И длину в 8 байт.

Simmike

Тоже попробовал через insert_one_table. Все получилось. Значительно быстрее через ОЛЕ, но вот не во всем разобрался, в частности
как изменть имена листов и
возможно сохранить и закрыть этот созданный файл Excel :?:

влад

Когда научишься, отпиши, как переименовывать вкладки. Самому скоро понадобится :!:

Правила форума

Метод insert_one_table (DOI)

Кто сейчас на конференции