BAPI: Удалить ЕО в ИП

inna

Подскажите BAPI: Удалить ЕО в ИП.

Удаляю поставки через 'BAPI_OUTB_DELIVERY_CHANGE'.
Но она отрабатывает если не было комплектования и соответсвенно ЕО (единиц обработки). Какой BAPi их удалить? Help :arrow:

Пономарев Артем

Вопрос не ясен.
Какие ЕО вы хотите удалить, если их не было?

inna

Пономарев Артем написал:

Вопрос не ясен.
Какие ЕО вы хотите удалить, если их не было?

Bapi для удаления имеющихся ЕО в поставке.

Пономарев Артем

Нет такой.
Правильный порядок: отвязать ЕО от поставки. Удалить ЕО (если сильно надо, особого смысла в этом уже нет).
Код:

Code:

  DATA: is_vbkok TYPE vbkok,
        lt_prot  TYPE TABLE OF prott.

  DATA: ls_flags     TYPE v51p_select_flags,
        ls_objects   TYPE hum_object,
        lt_objects   TYPE hum_object_t,

        lt_vekp      TYPE TABLE OF vekpvb,

        lt_hus       TYPE hum_venum_t,
        ls_header51  TYPE header51,

        lt_messages  TYPE huitem_messages_t.

  DATA: l_lin_cnt TYPE i.

  FIELD-SYMBOLS: <lfs_s_vekp> TYPE vekpvb.

  CALL FUNCTION 'HU_PACKING_REFRESH'.

  ls_header51-object = '03'.
  ls_header51-objkey = i_vbeln.

  ls_objects-object = '03'.
  ls_objects-objkey = i_vbeln.
  APPEND ls_objects TO lt_objects.

  ls_flags-add_and_exp = 'X'.  "set flag for save selected HU's data in global memory

  CALL FUNCTION 'V51P_FILL_GT'
    EXPORTING
      is_flags    = ls_flags
      is_header51 = ls_header51
      it_objects  = lt_objects
    IMPORTING
      et_vekp     = lt_vekp
    EXCEPTIONS
      OTHERS      = 0.

  LOOP AT lt_vekp ASSIGNING <lfs_s_vekp>.

    APPEND <lfs_s_vekp>-venum TO lt_hus.

  ENDLOOP.

  DESCRIBE TABLE lt_hus LINES l_lin_cnt.

  IF l_lin_cnt EQ 0. RETURN. ENDIF.

  CALL FUNCTION 'V51P_DELETE_RELATIONSHIP'
    EXPORTING
      it_hus      = lt_hus
    IMPORTING
      et_messages = lt_messages
    EXCEPTIONS
      OTHERS      = 99.

  CALL FUNCTION 'HU_PACKING_UPDATE'
    EXPORTING
      if_synchron = abap_false.

  is_vbkok-vbeln_vl      = i_vbeln.

  is_vbkok-packing_final = abap_true.

  CALL FUNCTION 'WS_DELIVERY_UPDATE'
    EXPORTING
      vbkok_wa = is_vbkok
      synchron = abap_true
      commit   = abap_false
      delivery = i_vbeln
    TABLES
      prot     = lt_prot
    EXCEPTIONS
      OTHERS   = 99.

  IF sy-subrc = 0.
    COMMIT WORK AND WAIT.
    i_subrc = 0.
  ELSE.
    ROLLBACK WORK.
    i_subrc = 1.
  ENDIF.

inna

скип

Пономарев Артем

Поставка входящая или исходящая?
Если исходящая, меняйте

Code:

  ls_header51-object = '01'.
  ls_header51-objkey = i_vbeln.

  ls_objects-object = '01'.
  ls_objects-objkey = i_vbeln.
  APPEND ls_objects TO lt_objects. 

З.Ы.: Оверквотинг - это зло.

З.З.Ы.: Иногда нужно и самому подумать

Кстати, commit то где? естественно не отвяжется.

inna

Пономарев Артем написал:

Поставка входящая или исходящая?
Если исходящая, меняйте

Code:

  ls_header51-object = '01'.
  ls_header51-objkey = i_vbeln.

  ls_objects-object = '01'.
  ls_objects-objkey = i_vbeln.
  APPEND ls_objects TO lt_objects. 

Кстати, commit то где? естественно не отвяжется.

спасибо,попробую.
коммит опущен, но он есть

еще один вопросик насчет ls_objects-object = '01'.
где посмотреть что 01 - исх а 03 - вх поставка и др значения

Jelena

inna написал(а):

еще один вопросик насчет ls_objects-object = '01'.
где посмотреть что 01 - исх а 03 - вх поставка и др значения

В домене HU_OBJECT, куда можно попасть напрямую из SE11, либо сериями двойных щелчков прямо из ls_objects.

inna

Спасибо, все получилось замечательно, единственное пришлось заменить:

IF sy-subrc = 0.
COMMIT WORK AND WAIT.
"i_subrc = 0.
ELSE.
ROLLBACK WORK.
"i_subrc = 1.
ENDIF.

на:

IF sy-subrc = 0.
CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'.
else.
CALL FUNCTION 'BAPI_TRANSACTION_ROLLBACK'.
endif.

andry_moz

inna написал(а):

Подскажите BAPI: Удалить ЕО в ИП.

Каким BAPI создаются ЕО единицы обработки (по аналогии с HU02)? - BAPI_HU_CREATE ?
И какие BAPI для привязки к исх/вх поставкам и упаковка материала?

NickS

andry_moz написал:

inna написал(а):

Подскажите BAPI: Удалить ЕО в ИП.

Каким BAPI создаются ЕО единицы обработки (по аналогии с HU02)? - BAPI_HU_CREATE ?
И какие BAPI для привязки к исх/вх поставкам и упаковка материала?

что то вспоминаю что для исходящей поставки все делается с помошью 'WS_DELIVERY_UPDATE' заполнением
TABLES
verko_tab
verpo_tab

andry_moz

Отвязываем ЕО с удалением в исх поставке. Замечания приветствуются.

Code:

DATA: is_vbkok TYPE vbkok,
        lt_prot  TYPE TABLE OF prott.

  DATA: ls_flags     TYPE v51p_select_flags,
        ls_objects   TYPE hum_object,
        lt_objects   TYPE hum_object_t,
        lt_vekp      TYPE TABLE OF vekpvb,
        lt_hus       TYPE hum_venum_t,
        ls_header51  TYPE header51,
        lt_messages  TYPE huitem_messages_t,
        LS_HU TYPE HUM_VENUM.

  DATA: l_lin_cnt TYPE i.

  FIELD-SYMBOLS: <lfs_s_vekp> TYPE vekpvb.

  CALL FUNCTION 'HU_PACKING_REFRESH'.

  ls_header51-object = '01'.
  ls_header51-objkey = i_vbeln. " Исх. поставка

  ls_objects-object = '01'.
  ls_objects-objkey = i_vbeln.
  APPEND ls_objects TO lt_objects.

  ls_flags-add_and_exp = 'X'.  "set flag for save selected HU's data in global memory

  CALL FUNCTION 'V51P_FILL_GT'
    EXPORTING
      is_flags    = ls_flags
      is_header51 = ls_header51
      it_objects  = lt_objects
    IMPORTING
      et_vekp     = lt_vekp
    EXCEPTIONS
      OTHERS      = 0.

data: t_exidv type EXIDV.
data: return type BAPIRET2 OCCURS 0.

  LOOP AT lt_vekp ASSIGNING <lfs_s_vekp>.
    APPEND <lfs_s_vekp>-venum TO lt_hus.

    CALL FUNCTION 'HU_GET_HUS'
        EXPORTING
           if_lock_hus = 'X'
           it_venum    = lt_hus.     "it_venum contains l_venum

    CALL FUNCTION 'V51F_DELETE_HU'
        EXPORTING
           if_venum    = <lfs_s_vekp>-venum.

    CALL FUNCTION 'HU_POST'.

  ENDLOOP.

  DESCRIBE TABLE lt_hus LINES l_lin_cnt.

  IF l_lin_cnt EQ 0. RETURN. ENDIF.

  CALL FUNCTION 'V51P_DELETE_RELATIONSHIP'
    EXPORTING
      it_hus      = lt_hus
    IMPORTING
      et_messages = lt_messages
    EXCEPTIONS
      OTHERS      = 99.

   CALL FUNCTION 'HU_PACKING_UPDATE'
    EXPORTING
      if_synchron = abap_false.


  is_vbkok-vbeln_vl      = i_vbeln.
  is_vbkok-packing_final = abap_true.

  CALL FUNCTION 'WS_DELIVERY_UPDATE'
    EXPORTING
      vbkok_wa = is_vbkok
      synchron = abap_true
      commit   = abap_false
      delivery = i_vbeln
    TABLES
      prot     = lt_prot
    EXCEPTIONS
      OTHERS   = 99.


  IF sy-subrc = 0.
    COMMIT WORK AND WAIT.
*    i_subrc = 0.
  ELSE.
    ROLLBACK WORK.
*    i_subrc = 1.
  ENDIF.

holocron

andry_moz написал:

Отвязываем ЕО с удалением в исх поставке. Замечания приветствуются.

Code:

....
  LOOP AT lt_vekp ASSIGNING <lfs_s_vekp>.
    APPEND <lfs_s_vekp>-venum TO lt_hus.

    CALL FUNCTION 'HU_GET_HUS'
        EXPORTING
           if_lock_hus = 'X'
           it_venum    = lt_hus.     "it_venum contains l_venum

    CALL FUNCTION 'V51F_DELETE_HU'
        EXPORTING
           if_venum    = <lfs_s_vekp>-venum.

    CALL FUNCTION 'HU_POST'.

  ENDLOOP.
  ....

вот тут странная конструкция. lt_hus все растет и растет... нет?

Правила форума

BAPI: Удалить ЕО в ИП

Кто сейчас на конференции