0000             04   10       *** CREATE INFOTYPE 41 WHEN HIRING  MEXICO ****
0000             04   11   P   P0000-MASSN='01'
0000             04   12   P   T001P-MOLGA='32'
0000             04   13   I   INS,0041,,,(P0000-BEGDA),(P0000-ENDDA)/D
0000             04   14   W   P0041-DAR01='01'
0000             04   15   W   P0041-DAT01=P0000-BEGDA
0000             04   16   W   P0041-DAR02='V1'
0000             04   17   W   P0041-DAT02=P0000-BEGDA
0000             04   18   F   REDUCE_V1_BY_ONE_DAY(HMXDYNM0)

*&---------------------------------------------------------------------*
*&      Form  REDUCE_V1_BY_ONE_DAY
*&---------------------------------------------------------------------*
*      Action:
*        the value of the date of type 'V1', which signifies
*        'Fecha ref.vacac.', is reduced by one
*      Requirements:
*        in table T588Z the country and the appropriate personnel action
*        should be checked and in the correct case a new infotype 41
*        record should be created with the date type 'V1' set to
*        the hiring date; afterwards this routine is called
*      Background:
*        it is necessary to generate absence contingents starting
*        from the hiring date and lasting exactly one year; if the
*        hiring date is used directly and in the customizing of
*        table T559V the end date of validity for absence contingents
*        is defined as 12 months later, then the resulting absence
*        contingents are valid for one year plus one day
*----------------------------------------------------------------------*
FORM REDUCE_V1_BY_ONE_DAY.
  DATA: L_TYPE_STARTSTR(9) TYPE C,
        L_DATE_STR(11)     TYPE C,
        L_TEMP_STR(11)     TYPE C,
        L_CHAR(2)          TYPE C,
        L_TYPE             LIKE P0041-DAR01,
        L_DATE             LIKE P0041-DAT01,
        L_SEQNR            LIKE INITIAL_VALUES-SEQNR.
  CONSTANTS: LC_V1               LIKE P0041-DAR01 VALUE 'V1',
             LC_TYPE_STARTSTR(9) TYPE C           VALUE 'P0041-DAR',
             LC_DATE_STARTSTR(9) TYPE C           VALUE 'P0041-DAT'.

  LOOP AT INITIAL_VALUES.
    L_TYPE_STARTSTR = INITIAL_VALUES-FIELD_NAME(9).
    CHECK L_TYPE_STARTSTR EQ LC_TYPE_STARTSTR.
*   this entry corresponds to a date type of infotype 41.

    L_TYPE = INITIAL_VALUES-FIELD_VALUE.
    CHECK L_TYPE EQ LC_V1.
*   this entry corresponds to the date type V1.

*   construct the IT41 field name that contains the date
    L_CHAR = INITIAL_VALUES-FIELD_NAME+9(2).
    CONCATENATE LC_DATE_STARTSTR L_CHAR INTO L_DATE_STR.
    L_SEQNR = INITIAL_VALUES-SEQNR.
    EXIT.

  ENDLOOP.

  CHECK NOT L_DATE_STR IS INITIAL.
* for IT41 the V1 date type was set

  LOOP AT INITIAL_VALUES WHERE SEQNR EQ L_SEQNR.
    L_TEMP_STR = INITIAL_VALUES-FIELD_NAME(11).
    CHECK L_TEMP_STR EQ L_DATE_STR.
*   this register contains the required date.

    L_DATE = INITIAL_VALUES-FIELD_VALUE.
    IF NOT L_DATE IS INITIAL.
      L_DATE = L_DATE - 1.
      INITIAL_VALUES-FIELD_VALUE = L_DATE.
      MODIFY INITIAL_VALUES.
    ENDIF.

    EXIT.
  ENDLOOP.

ENDFORM.                    " REDUCE_V1_BY_ONE_DAY

PROGRAM  ZPFORM01.
TABLES: RP50D,                    "return fields for dynamic actions
        PRELP.                    "buffer personal master data

* Compute date
FORM COMPUTE_DATE.
  RP50D-DATE1 = PRELP-BEGDA - 14.
ENDFORM.