передача динамической переменной в форму, для обозначения поля в структуре.

panna

Здравствуйте, обитатели форума.
Помогите, пожалуйста.
Хочу написать форму, которую буду использовать для заполнения однотипных полей таблицы. В блоке USING хочу указать поле структурки, которой будет присвоено вычисленное значение. Вот краткий код, (красным выделено то, как я хочу, но не получается. если вместо красного ставить четкое значение код отрабатывает корректно) может так будет понятней:

PERFORM sum USING '0000000433' 'gs_data-compens'.
PERFORM sum USING '0000000435' 'gs_data-effect'.
..........................................................
..........................................................
FORM sum USING i_atinn value(_i_field) TYPE fieldname.

SELECT werka poper SUM( atflv ) AS l_count
INTO CORRESPONDING FIELDS OF TABLE gt_c_data
FROM ausp AS a INNER JOIN zrp_info_s_table AS t ON a~objek = t~objek
WHERE atinn = i_atinn AND
poper IN s_poper AND
werka IN s_bukrs
GROUP BY werka poper. "получаем маленькую табличку с нужными результатами

FIELD-SYMBOLS <fs_count> TYPE g_data_count_type.

LOOP AT gt_c_data ASSIGNING <fs_count>. " перекладываем в поле <compens> общей, большой таблички, по уже имеющимся строкам с БЕ и периодами
CLEAR gs_data.
MOVE-CORRESPONDING <fs_count> TO gs_data.
(_i_field) = <fs_count>-l_count. " тут я хочу динамически назначать поле структуры gs_data, т.к. при разных значениях i_atinn будут заполняться разные поля этой структуры.
COLLECT gs_data INTO gt_data.
ENDLOOP.

ENDFORM.

8051core

Можно передавать как строку с именем поля, а внутри формы уже делать ASSIGN к нужному полю структуры

Пономарев Артем

panna, вы не совсем верно представляете себе механизм передачи и адресации данных.

В вашем примере вы присваиваете значение локальной переменной внутри формы. 8051core дал вам правильный совет. Передавайте в форму структуру gs_data и пользуйтесь оператором ASSIGN для адресации нужного поля по имени _i_field.

Удав

Обычно это делается так:

Code:

ASSIGN (_i_field) TO <FS>.
IF sy-subrc = 0.
  <FS> =  <fs_count>-l_count.
ENDIF.

Но в общем случае имеест смысл задуматься - может имеет смысл связать признак классификации с именем поля (например назвать поле по имени признака):
таблица lt_char_map
ATINN ATNAM
0000000433 COMPENS
0000000435 EFFECT

Code:

SELECT a~atnam t~werka t~poper SUM( a~atflv )
INTO CORRESPONDING FIELDS OF TABLE gt_c_data
FROM ausp AS a 
INNER JOIN zrp_info_s_table AS t ON a~objek = t~objek
FOR ALL ENTRIES IN lt_char_map
WHERE a~atinn = lt_char_map~atinn AND
      t~poper IN s_poper AND
     t~werka IN s_bukrs
GROUP BY a~atnam t~werka t~poper. "получаем маленькую табличку с нужными результатами

LOOP AT gt_c_data ASSIGNING <fs_count>. " перекладываем в поле <compens> общей, большой таблички, по уже имеющимся строкам с БЕ и периодами
  CLEAR gs_data.
  MOVE-CORRESPONDING <fs_count> TO gs_data.
  ASSIGN COMPONENT <fs_count>-ATNAM OF STRUCTURE gs_data TO <FS>.
  IF sy-subrc = 0.
    <FS> =  <fs_count>-l_count.
  ENDIF.
  COLLECT gs_data INTO gt_data.
ENDLOOP. 

broker.chelny

Для вашего примера думаю лучше использовать макрос.

Правила форума

передача динамической переменной в форму, для обозначения поля в структуре.

Кто сейчас на конференции