Подскажите код транзакции ,которая позволила бы посмотреть какие расширения используются в данной транзакции

Тоже хотел бы знать такую транзакцию

Пока пользуюсь SMOD - Утилиты - Поиск.

Или же войте в текст программы, которая привязана к интересующей транзакции и задать поиск по вхождению CUSTOMER-FUNCTION....

REPORT ZBSVS_USEREXITS_VIEW NO STANDARD PAGE HEADING .


************************************************************
* TABLES
************************************************************

TABLES :
tstc, "SAP-коды транзакций
tstct, "Тексты кодов транзакций
tadir, "Каталог объектов репозитария
modsapt, "Краткие тексты к SAP-расширениям
modact, "Модификации
trdir, "Системная таблица TRDIR
tfdir, "Функциональный модуль
enlfdir "Дополнительные атрибуты для функциональных модулей
.

*************************************************************
* DATA
*************************************************************
DATA : jtab LIKE tadir OCCURS 0 WITH HEADER LINE.
DATA : field1(30).
DATA : v_devclass LIKE tadir-devclass.


*************************************************************
* SCREEN
*************************************************************
SELECTION-SCREEN BEGIN OF BLOCK scr1 WITH FRAME TITLE text-001.
PARAMETERS : p_tcode LIKE tstc-tcode OBLIGATORY.
SELECTION-SCREEN END OF BLOCK scr1.


*************************************************************
* START-OF-SELECTION
*************************************************************
START-OF-SELECTION.
SELECT SINGLE * FROM tstc WHERE tcode EQ p_tcode.

IF sy-subrc EQ 0.
SELECT SINGLE * FROM tadir WHERE pgmid = 'R3TR'
AND object = 'PROG'
AND obj_name = tstc-pgmna.
MOVE : tadir-devclass TO v_devclass.


IF sy-subrc NE 0.
SELECT SINGLE * FROM trdir WHERE name = tstc-pgmna.
IF trdir-subc EQ 'F'.
SELECT SINGLE * FROM tfdir WHERE pname = tstc-pgmna.
SELECT SINGLE * FROM enlfdir WHERE funcname = tfdir-funcname.
SELECT SINGLE * FROM tadir WHERE pgmid = 'R3TR'
AND object = 'FUGR'
AND obj_name EQ enlfdir-area.
MOVE : tadir-devclass TO v_devclass.
ENDIF.
ENDIF.


SELECT * FROM tadir INTO TABLE jtab WHERE pgmid = 'R3TR'
AND object = 'SMOD'
AND devclass = v_devclass.
SELECT SINGLE * FROM tstct WHERE sprsl EQ sy-langu AND
tcode EQ p_tcode.
FORMAT COLOR COL_POSITIVE INTENSIFIED OFF.
WRITE:/(19) 'Transaction Code - ',
20(20) p_tcode,
45(50) tstct-ttext.
SKIP.


IF NOT jtab[] IS INITIAL.
WRITE:/(95) sy-uline.
FORMAT COLOR COL_HEADING INTENSIFIED ON.
WRITE:/1 sy-vline,
2 'Exit Name',
21 sy-vline ,
22 'Description',
95 sy-vline.


WRITE:/(95) sy-uline.


LOOP AT jtab.
SELECT SINGLE * FROM modsapt WHERE sprsl = sy-langu AND
name = jtab-obj_name.
FORMAT COLOR COL_NORMAL INTENSIFIED OFF.
WRITE:/1 sy-vline,
2 jtab-obj_name HOTSPOT ON,
21 sy-vline ,
22 modsapt-modtext,
95 sy-vline.
ENDLOOP.
WRITE:/(95) sy-uline.
DESCRIBE TABLE jtab.
SKIP.
FORMAT COLOR COL_TOTAL INTENSIFIED ON.
WRITE:/ 'No of Exits:' , sy-tfill.
ELSE.
FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
WRITE:/(95) 'No User Exit exists'.
ENDIF.

ELSE.
FORMAT COLOR COL_NEGATIVE INTENSIFIED ON.
WRITE:/(95) 'Transaction Code Does Not Exist'.
ENDIF.


END-OF-SELECTION.
*************************************************************
AT LINE-SELECTION.
GET CURSOR FIELD field1.
CHECK field1(4) EQ 'JTAB'.
SET PARAMETER ID 'MON' FIELD sy-lisel+1(10).
CALL TRANSACTION 'SMOD' AND SKIP FIRST SCREEN.




*************************************************************

Последняя прога хорошая, но не универсальная...

to Egal - вовсе необязательно расширения относятся к тем же классам разработки, что и транзакции... Иногда SAP так запрячет...

"Коня! Коня! Полцарства за коня!" (с)...

Так "расширения" - понятие довольно емкое - в свое время на форуме считали сколько может быть разных законных способов. Те проги что выше - это способ найти customer-exit-ы, а кроме них есть еще BADI, OPEN-FI, филдэкзиты и т.д. и т.п.

Тогда SE84 в руки!