Не получается создать объект класса динамически

karepan

Добрый день!

Почему не получается динамически создать объект класса cl_airplane в коде, приведенном ниже?

Code:

TYPE-POOLS abap.

DATA: class TYPE string VALUE 'cl_airplane',
      r_class TYPE REF TO object,
      r_1 TYPE REF TO cl_airplane
      exc_ref TYPE REF TO cx_root,
      exc_text TYPE string,
      ptab TYPE abap_parmbind_tab,
      ptab_line TYPE abap_parmbind.

ptab_line-name  = 'IM_NAME'.
ptab_line-kind  = cl_abap_objectdescr=>exporting.
GET REFERENCE OF 'hhh' INTO ptab_line-value.
INSERT ptab_line INTO TABLE ptab.

ptab_line-name  = 'IM_PLANETYPE'.
ptab_line-kind  = cl_abap_objectdescr=>exporting.
GET REFERENCE OF 'ggg' INTO ptab_line-value.
INSERT ptab_line INTO TABLE ptab.

TRY.
    CREATE OBJECT r_class TYPE (class)
                  PARAMETER-TABLE ptab.
  CATCH cx_sy_create_object_error INTO exc_ref.
    exc_text = exc_ref->get_text( ).
    MESSAGE exc_text TYPE 'I'.
ENDTRY.


CREATE OBJECT r_1
  EXPORTING im_name = 'hhh'
    im_planetype = 'ggg'.

Выдается ошибка:
The object could not be created: The class cl_airplane does not exist.

Хотя строчкой ниже успешно создается такой же объект r_1 с явно заданным типом!

Помогите, пожалуйста, начинающему

LinevskiySV

Code:

TYPE-POOLS abap.

DATA: class TYPE string VALUE 'cl_airplane',

В таком деле всегда важен регистр. Переведите имя класса в верхний регистр.
схоже

karepan

LinevskiySV написал:

Code:

TYPE-POOLS abap.

DATA: class TYPE string VALUE 'cl_airplane',

В таком деле всегда важен регистр. Переведите имя класса в верхний регистр.

Спасибо тебе, добрый человек!

niemda

Можно ещё таким образом поступить:
В фабрике:

Code:

  data: lv_clsname type abap_abstypename, ref type ref to object.
  if clsname is supplied.
    lv_clsname = clsname.
    translate lv_clsname to upper case.
  elseif classdescr is supplied.
    classdescr->load_class(  ).
    lv_clsname = classdescr->absolute_name.
  endif.

  create object ref
    type
      (lv_clsname)
    exporting
      structure_name = structure_name.
  result = ref. return.

Для создания экземпляра нужно так называемое "абсолютное" имя класса. Для локального: с программой или пулом, в котором этот класс находится.

А при создании экземпляра передаём экземпляр cl_abap_classdescr.

Code:

data: abap_classdescr type ref to cl_abap_classdescr.
abap_classdescr ?= cl_abap_classdescr=>describe_by_name( 'YOUR_CLASS' ).

object ?= class=>factory( classdescr = abap_classdescr ).

Правила форума

Не получается создать объект класса динамически

Кто сейчас на конференции