копирование 2-х внут. таблиц с разными структурами

chita

Прошу не судить строго, если если это элементарно, но никак не получается, скопировать содержимое из 1 внут. таблицы в другую с разными структурами. в своем методе создаю динамическую внут. таблицу и в нее надо переписать данные из другой таблицы (переданную в метод как параметр outtab Type standard table). В 1-ой динамической таблице имеются поля как и в другой таблице, но не наоборот.

Code:

method SAVE_DATA.

field-symbols: <dyn_table> type standard table  ,
                     <dyn_wa> TYPE ANY.

data: dy_table type ref to data,
        ifc type lvc_t_fcat.

* Create dynamic internal table 
  call method cl_alv_table_create=>create_dynamic_table
               exporting
                  it_fieldcatalog = ifc
               importing
                  ep_table        = dy_table.

  assign dy_table->* to <dyn_table>.

************** нужно что типа этого************
MOVE outtab to <dyn_table>.
*********************************************

endmethod.

Хотел записать через loop at .... MOVE-CORRESPONDING ... endloop. Но не могу создать стуктуру для таблицы переданной как параметр. (для динам. содается без проблемм).
Заранее всем благодарен за помощь.

Кодер

Примерно так

Code:

  field-symbols
    : <lsrc>    type any
    , <ltrg>    type any
    .
.....
loop at imt_src asigning <lsrc>.
  append initial line to <lt_trg> assigning <ltrg>.
  move-corresponding <lsrc> to <ltrg>.
endloop.

<lt_trg> - ссылка на вашу динамическую таблу
imt_src - исходная таблица

RA

Для лентяев есть

Code:

CALL METHOD cl_reca_data_services=>move_corresponding_table

chita

To Кодер.
Спасибо большое, помогло

а вот cl_reca_data_services=>move_corresponding_table система не понимает :cry:

видимо не судьба мне ленится, но все равно спасибо за помощь...

Gustav

chita написал:

а вот cl_reca_data_services=>move_corresponding_table система не понимает :cry:

Та же фигня. Но, видимо, я был совсем ленив, поэтому решил поискать в тр. SE16 по таблице SEOCOMPO для CMPNAME = MOVE_CORRESPONDING_TABLE.

Нашлось 3 класса и соответственно 3 одноименных статических метода:
CL_ISSR_TOOLS=>move_corresponding_table
CL_REUT_TEST_SERVICES=>move_corresponding_table
CL_REXC_FC_SERVICES=>move_corresponding_table

Все они - абсолютные (явно копи-пастные) копии друг друга следующего вида:

Code:

METHOD MOVE_CORRESPONDING_TABLE .

  DATA:
    ls_trg   TYPE REF TO data.

  FIELD-SYMBOLS:
    <ls_src> TYPE ANY,
    <ls_trg> TYPE ANY.

* create one line of data of target type
  CREATE DATA ls_trg LIKE LINE OF ct_trg.
  ASSIGN ls_trg->* TO <ls_trg>.

* move-corresponding each line of SRC to TRG line
  LOOP AT it_src ASSIGNING <ls_src>.
    MOVE-CORRESPONDING <ls_src> TO <ls_trg>.
    APPEND <ls_trg> TO ct_trg.
  ENDLOOP.

  FREE ls_trg.

ENDMETHOD.

Годы создания классов: 2000, 2003, 2005 соответственно. Поэтому исторической справедливости ради, а также краткости названия для, можно остановиться на первом из них: cl_issr_tools=>move_corresponding_table.

PP

В 4.7 из данных классов есть только CL_ISSR_TOOLS, но в нем нет метода move_corresponding_table

Правила форума

копирование 2-х внут. таблиц с разными структурами

Кто сейчас на конференции