передача в METHOD значения через importing - exporting

Alraun

подскажите, что можно сделать?
есть метод:

Code:

METHODS popup IMPORTING 
             TITLE TYPE C     
             TAB TYPE C    
             T_TAB TYPE C. 

вызываю метод, передаю параметры:

Code:

CALL METHOD popup_select->popup EXPORTING      
                     TITLE = 'Choose documents'
                     TAB = 'ZBKPF' 
                     T_TAB = ZBKPF.

implementation такой:

Code:

METHOD popup.                            
  CALL FUNCTION 'REUSE_ALV_POPUP_TO_SELECT'   
  EXPORTING                                 
    i_title = TITLE                         
    i_tabname = TAB           
    it_fieldcat = lt_fcat          
  TABLES                                    
    t_outtab = T_TAB.        
 ENDMETHOD.    

TITLE и TAB прекрасно передаются, как передать T_TAB не знаю

ZBKPF - внутренняя таблица, определяется в определении класса.

РМщик

может нужно T_TAB[] ?

РМщик

в смысле ZBKPF[]

Виктор(Минск)

М.б. так:

Code:

types: t_mtable type table of ZBKPF.

METHODS popup IMPORTING
             TITLE TYPE C     
             TAB TYPE C   
             T_TAB TYPE t_mtable. 

CALL METHOD popup_select->popup EXPORTING     
                     TITLE = 'Choose documents'
                     TAB = 'ZBKPF'
                     T_TAB = ZBKPF[]. 

?

Сергей Королев

Если структура таблицы не важна (например, она нужна только для передачи в ALV, то можно так описать:

Code:

METHODS popup IMPORTING 
             TITLE TYPE C     
             TAB TYPE C    
             T_TAB TYPE ANY TABLE. 

Вызывается так:

Code:

CALL METHOD popup_select->popup EXPORTING      
                     TITLE = 'Choose documents'
                     TAB = 'ZBKPF' 
                     T_TAB = ZBKPF[].

Если внтури метода обрабатывается структура, то нужно описать тип таблицы (можно в SE11), и тогда в определении метода указывать этот тип и передавать внутренние таблицы только такой структуры.

RoadRunner

Если класс свой, можно объявить глобальный тип этой таблицы для использования в этом классе.

Alraun

не помогает ничего.
мне же нужно, чтобы при втором вызове метода, можно было в функцию передать другую внутреннюю таблицу, например, ZBSEG вместо ZBKPF.

Виктор(Минск)

Цитата:

не помогает ничего.

Не верю! ANY TABLE дожно подойти 100про. :shock:

Сергей Королев

Пример работает в 4.6с. Обратите внимание на CHANGING, если табличный параметр описать как IMPORTING, то валится в дамп, так как функция пытается с таблицей работать в режиме записи.

Code:

REPORT zz_decl_test .

*---------------------------------------------------------------------*
*       CLASS lcl_test DEFINITION
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
CLASS lcl_test DEFINITION.
  PUBLIC SECTION.
    METHODS popup IMPORTING
                 value(tabname) TYPE dd02l-tabname
                 CHANGING
                 t_tab TYPE STANDARD TABLE.

ENDCLASS.

*---------------------------------------------------------------------*
*       CLASS lcl_test IMPLEMENTATION
*---------------------------------------------------------------------*
*       ........                                                      *
*---------------------------------------------------------------------*
CLASS lcl_test IMPLEMENTATION.
  METHOD popup.
    CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
         EXPORTING
              i_structure_name = tabname
         TABLES
              t_outtab         = t_tab
         EXCEPTIONS
              program_error    = 1
              OTHERS           = 2.
  ENDMETHOD.
ENDCLASS.

DATA:
  test TYPE REF TO lcl_test,
  zbkpf TYPE TABLE OF bkpf,
  zbseg TYPE TABLE OF bseg.

START-OF-SELECTION.
  CREATE OBJECT test.

  CALL METHOD test->popup
    EXPORTING tabname = 'BKPF'
    CHANGING  t_tab = zbkpf.

  CALL METHOD test->popup
    EXPORTING tabname = 'BSEG'
    CHANGING  t_tab = zbseg.

Alraun

хм, а если zbkpf и zbseg в class definition описаны, то такое не пойдёт? у меня именно так. причём, что в private, что в public - результат один.

Alraun

да, помогло вынесение таблиц из определения класса (хм, только как-то некрасиво, ну да ладно) и TYPE STANDARD TABLE, всем спасибо!

Правила форума

передача в METHOD значения через importing - exporting

Кто сейчас на конференции