Спрятать закладки в кнопке extentions в select-options

qq

Хочу спрятать закладки с интервалами и с невключеными значениями.
мне почему то кажется, чтоя где-то читал, как это можно сделать, но найти не могу.

nicky555

Уж сколько раз твердили миру...

Цитата:

Параметры Selection-Screen'а можно всячески ограничивать. Для этого можно воспользоваться ФМ SELECT_OPTIONS_RESTRICT.

Ниже приведен пример, ограничивающий выбор интервалов в Select-Options (но не многократный выбор !). Подробнее - см. справку к Функциональному Модулю.

Пример:

Code:

TABLES t001.

SELECT-OPTIONS s_parms FOR t001-bukrs.

* Вспомогательные типы
TYPE-POOLS sscr.

* Объект RESTRICTION параметра
DATA restrict TYPE sscr_restrict.

* Обязательные подобъекты объекта RESTRICT
DATA: opt_list TYPE sscr_opt_list,
      ass      TYPE sscr_ass.


INITIALIZATION.
* только ПАРАМЕТР
  CLEAR opt_list.
  MOVE 'JUST_EQ' TO opt_list-name.
  MOVE 'X' TO opt_list-options-eq.
  APPEND opt_list TO restrict-opt_list_tab.

* применяется только к S_PARAMS
MOVE: 'S' TO ass-kind,
      'S_PARMS' TO ass-name,
      '*' TO ass-sg_main,
      'JUST_EQ' TO ass-op_main.
APPEND ass TO restrict-ass_tab.

* ограничение вызовом ФМ
  CALL FUNCTION 'SELECT_OPTIONS_RESTRICT'
    EXPORTING
      restriction                = restrict
    EXCEPTIONS
      too_late                   = 1
      repeated                   = 2
      not_during_submit          = 3
      db_call_after_report_call  = 4
      selopt_without_options     = 5
      selopt_without_signs       = 6
      invalid_sign               = 7
      report_call_after_db_error = 8
      empty_option_list          = 9
      invalid_kind               = 10
      repeated_kind_a            = 11
      OTHERS                     = 12.
  IF sy-subrc NE 0.
*   TODO: обработка ошибок
  ENDIF.


AT SELECTION-SCREEN OUTPUT.
* подавить вывод на экран HIGH-параметра
  LOOP AT SCREEN.
    IF screen-name EQ 'S_PARMS-HIGH'.
      screen-invisible = '1'.
      MODIFY SCREEN.
    ENDIF.
  ENDLOOP.

qq

ОНО! ЭТО ОНО!

ЧЕСТНОЕ СЛОВО, ПРЕЖДЕ ЧЕМ СПРОСИТЬ ИСКАЛ.
Спасибо!

EHOT

я видимо чего-то не понял, а no-intervals и no-extensions тут не канают ?

Сергей Королев

no intervals убирает поле HIGH с экрана, но если на кнопку extensions нажать, то там все равно можно ввести интервалы. А вот про SELECT_OPTIONS_RESTRICT я и не знал.

EHOT

Сергей Королев написал:

no intervals убирает поле HIGH с экрана, но если на кнопку extensions нажать, то там все равно можно ввести интервалы. А вот про SELECT_OPTIONS_RESTRICT я и не знал.

а точно ... хотя зачем уж так сильно то извращаться

...
зы: тож не знал ...

Karmen

Здравствуйте!
Решил не создавать новую тему.. эта, думаю, подходящая тема..
Хотел в множественном выборе скрыть вкладки "Отдельные значения" и "Интервалы" с красными светофорами, то есть, вкладки которые позволяют перечислять исключаемые значения.
Экран - свой нарисованный(скажем 110). Там создал подэкран subscr1. В главной программе определил так же подэкран с пом. конструкции

Code:

SELECTION-SCREEN BEGIN OF SCREEN 1001 AS SUBSCREEN.
SELECTION-SCREEN BEGIN OF BLOCK a.
SELECT-OPTIONS: 
s_field1 FOR table1-field1, 
s_field2 FOR table1-field2.
SELECTION-SCREEN END OF BLOCK a.
SELECTION-SCREEN END OF SCREEN 1001 .  

и в PBO и PAI включил
CALL SUBSCREEN subscr1 INCLUDING sy-cprog '1001'.
и
CALL SUBSCREEN subscr1 соответственно.

Подэкран нормально отображается, там появились поля s_field1, s_field2 с кнопками множественного выбора. Хотелось бы убрать возможность исключать значения, то есть чтобы возможно было только перечислять нужные.
1) Для этого интересовался опциями SELECT-OPTIONS(NO-EXTENSION, NO INTERVALS - первый скрывает вообще кнопку множественного выбора, а второй скрывает интервалы в множественного выбора, но возможность перечислять исключаемые значения остается).
2) Попробовал использовать ФМ SELECT_OPTIONS_RESTRICT но не помогает. Может я не правильно пользуюсь? вот фрагмент настройки:

Code:

  ls_opt_list-name       = 'JUST_EQ' .
  ls_opt_list-options-eq = 'X' .
  ls_opt_list-options-nb = space.
  ls_opt_list-options-ne = space.
  APPEND ls_opt_list TO ls_restrict-opt_list_tab .
  CLEAR ls_opt_list.

  ls_ass-kind = 'S' .
  ls_ass-name = 's_field1' .
  ls_ass-sg_main = 'I' .
  ls_ass-sg_addy = SPACE.
  ls_ass-op_main = 'JUST_EQ'.
  APPEND ls_ass TO ls_restrict-ass_tab .
  CLEAR ls_ass .

данный код я поставил после INITIALIZATION.
затем вызываю ФМ SELECT_OPTIONS_RESTRICT.

Видимо тут дело в типе программы. (так как INITIALIZATION. используется только для выполнимых программ). У меня главная программа -пулмодуль. Ставил в PBO нужного экрана - не срабатывает..

Karmen

похоже придется запрограммировать кнопку множественного выбора :-)

Правила форума

Спрятать закладки в кнопке extentions в select-options

Кто сейчас на конференции