Как динамически изменить ПрВы средства поиска

zIk

Как в программе заблокировать изменение параметров поиска?
В свойствах СредстваПоиска колонка ПрВы.

Он

Мы обсуждали с вами средства поиска, я приводил код, как пример динамического формирования параметров ср. поиска. Обратите внимание на

Code:

IF NOT otab-zuonr IS INITIAL. 
    CLEAR ltParam. 
    ltParam-FldName = 'EXTNUM'. 
    ltParam-DefaultVal = otab-zuonr. 
    APPEND ltParam TO ltParam. 
  ENDIF. 

Возможно, это то, что вы ищете

zIk

Мне надо Edit-Enable=false, а в исходнике Edit-Text="textextext".
Незнаю как можно "завести" исходник, чтобы потестировать?

Он

чтобы протестить, взять свое или стандартное средство поиска и указанным методом описать пару его параметров, как возвращаемых. Если вы сделаете в соответсвии с приведенным кодом, то вы сможе зафиксировать значение какого то парметра для которого укажите
ltParam-DefaultVal = otab-zuonr. Это значение пользователь не сможет изменить

flipper

zIk написал:

Как в программе заблокировать изменение параметров поиска?
В свойствах СредстваПоиска колонка ПрВы.

если я правильно вас понимаю, попробуйте так:

Code:

  DATA : lwa_fieldprop LIKE ddshfprop.
  
  CLEAR lwa_fieldprop.
  lwa_fieldprop-shlpseldis = '0'.  "/ сделать неактивным
  lwa_fieldprop-defaultval = '''VALUE'''.  "/ значение поля
  MODIFY shlp-fieldprop FROM lwa_fieldprop  
        TRANSPORTING shlpseldis defaultval
        WHERE fieldname = 'FIELD_NAME'.

zIk

Спасибо.

2flipper, 2Он - для простого СП работает, а вот для комплексного - как добраться до СП.

Он

Я лично с этим не боролся, была попытка у моего коллеги, по той методе, которую приводил, не вышло... Для выхода из ситуации они просто сделали элементарное средство поиска с необходимым набором полей.

zIk

есть такое как
shlp-INTDESCR-SELMEXIT Пользовательское средство поиска (search help exit) - очень похоже на то что надо.

from flipper:

Цитата:

в общем сделал так, вызвал через F4IF_FIELD_VALUE_REQUEST, комплексное СП, в callback программе задал ему в shlp-INTDESCR-SELMEXIT свой ФМ(стандарный) F4IF_SHLP_EXIT_EXAMPLE(где поставил точку прерывания), попал туда и там для всех элементарных СП в SHLP_TAB-INTDESCR-SELMEXIT задал опять же F4IF_SHLP_EXIT_EXAMPLE, и при переходе опять же попадаем в точку прерывания в F4IF_SHLP_EXIT_EXAMPLE

Спасибо всем - свет в конце туннеля вижу!

flipper

zIk написал:

есть такое как
shlp-INTDESCR-SELMEXIT Пользовательское средство поиска (search help exit) - очень похоже на то что надо.

from flipper:

Цитата:

в общем сделал так, вызвал через F4IF_FIELD_VALUE_REQUEST, комплексное СП, в callback программе задал ему в shlp-INTDESCR-SELMEXIT свой ФМ(стандарный) F4IF_SHLP_EXIT_EXAMPLE(где поставил точку прерывания), попал туда и там для всех элементарных СП в SHLP_TAB-INTDESCR-SELMEXIT задал опять же F4IF_SHLP_EXIT_EXAMPLE, и при переходе опять же попадаем в точку прерывания в F4IF_SHLP_EXIT_EXAMPLE

Спасибо всем - свет в конце туннеля вижу!

в твоей задаче, достаточно будет в пользовательском СП(ФМ) для комплексного, изменить атрибуты полей в таблице SHLP_TAB, которая является коллекцией элементарных СП включенных в комплексное....

zIk

Найденное решение задачи:

В экране

Code:

PROCESS on value-request.
  FIELD mytab-myfield MODULE shMy.

В программе

Code:

module shMy input.
  call function 'F4IF_FIELD_VALUE_REQUEST'
      exporting
          tabname           = ''
          fieldname         = ''
          searchhelp        = 'MYSH'
          callback_program  = sy-repid
          callback_form     = 'CB_F4_VALUE_REQUEST'
          DYNPPROG          = sy-repid
          DYNPNR            = SY-DYNNR
          DYNPROFIELD       = 'MYTAB-MYFIELD'
      tables
          return_tab        = return_tab
      exceptions
  .
endmodule.                 " shMy  INPUT

FORM cb_f4_value_request TABLES record_tab STRUCTURE seahlpres
                       CHANGING
                           shlp type shlp_descr
                           callcontrol like ddshf4ctrl.

SHLP-INTDESCR-SELMEXIT = 'ZMY_F4IF_SHLP_EXIT'.

endform.                    "CB_F4_VALUE_REQUEST

функциональный модуль...

Code:

FUNCTION ZMY_F4IF_SHLP_EXIT.
*"----------------------------------------------------------------------
*"*"Локальный интерфейс:
*"  TABLES
*"      SHLP_TAB TYPE  SHLP_DESCT
*"      RECORD_TAB STRUCTURE  SEAHLPRES
*"  CHANGING
*"     VALUE(SHLP) TYPE  SHLP_DESCR
*"     VALUE(CALLCONTROL) LIKE  DDSHF4CTRL STRUCTURE  DDSHF4CTRL
*"----------------------------------------------------------------------

  data: wa_props like ddshfprop
    , wa_tab like shlp_tab
    .

  loop at shlp_tab into wa_tab.
    loop at wa_tab-fieldprop into wa_props where FIELDNAME = 'BUKRS'.
      wa_props-SHLPSELDIS = 'X'.
      modify wa_tab-fieldprop from wa_props index sy-tabix.
    endloop.
    modify shlp_tab from wa_tab index sy-tabix
        transporting fieldprop.
  endloop.

ENDFUNCTION.

В итоге вызывается комплексное СП, в его элементарных СП поля задания БЕ (BUKRS) неактивны.

Правила форума

Как динамически изменить ПрВы средства поиска

Кто сейчас на конференции