Загрузить файл в базу

eskars

Добрый день.
Подскажите как можно загрузить Excell-ский файл в базу и при определенном действии(к примеру нажатие кнопки), чтобы этот файл открывался.

РМщик

Например, транзакция SMW0

eskars

РМщик написал(а):

Например, транзакция SMW0

Да согласен, с ее помощью как шаблон загнать файл можно. Также можно и через oaer. Но как за АВАР-ить кнопку, чтобы этот файл открывался?

РМщик

В качестве параметра - используй имя объекта, с которым
ты загрузил шаблон в SMW0

Code:

PROGRAM CH.

INCLUDE OLE2INCL.
DATA: ZFILENAME TYPE LOCALFILE.
DATA: H_EXCEL TYPE OLE2_OBJECT,
      H_MAPL TYPE OLE2_OBJECT.

PARAMETERS:  OBJID TYPE W3OBJID.


START-OF-SELECTION.
  CLEAR: ZFILENAME.
  PERFORM SHABL USING OBJID.
  IF NOT ZFILENAME IS INITIAL.
    CREATE OBJECT H_EXCEL 'EXCEL.APPLICATION'.
    SET PROPERTY OF H_EXCEL  'Visible' = 1.
    CALL METHOD OF H_EXCEL 'Workbooks' = H_MAPL.
    CALL METHOD OF H_MAPL 'Open'
      EXPORTING
      #1 = ZFILENAME.
    FREE OBJECT H_MAPL.
    FREE OBJECT H_EXCEL.
  ENDIF.

FORM SHABL USING V TYPE W3OBJID.
  DATA: SAPWORKDIR TYPE STRING.
  DATA:  KEY LIKE WWWDATATAB.
  DATA: OBJ LIKE WWWDATAID.
  DATA  MIME LIKE W3MIME OCCURS 100 WITH HEADER LINE.

  TABLES: WWWDATA.
  CLEAR: MIME, MIME[].

  CALL METHOD CL_GUI_FRONTEND_SERVICES=>GET_SAPGUI_WORKDIR
    CHANGING
      SAPWORKDIR = SAPWORKDIR.
  CONDENSE: V.
  CONCATENATE SAPWORKDIR '\' V '.XLT' INTO SAPWORKDIR.

  KEY-OBJID = V.
  KEY-RELID = 'MI'.
  MOVE-CORRESPONDING KEY TO OBJ.
  MOVE-CORRESPONDING KEY TO WWWDATA.
  IMPORT MIME FROM DATABASE WWWDATA(MI) ID OBJ.

  IF NOT MIME[] IS INITIAL.
    CALL FUNCTION 'GUI_DOWNLOAD'
      EXPORTING
        FILENAME = SAPWORKDIR
        FILETYPE = 'BIN'
      TABLES
        DATA_TAB = MIME[].
    ZFILENAME = SAPWORKDIR .
  ELSE.
    MESSAGE I742(BP) WITH 'Не найден шаблон'.
  ENDIF.

ENDFORM.           

eskars

Спасибо

РМщик

eskars написал(а):

Спасибо

кстати мне нравится именно этот способ хранения шаблонов....

влад

У меня небольшая проблемка. Этот код:

Code:

    CALL FUNCTION 'GUI_DOWNLOAD'
      EXPORTING
        FILENAME = SAPWORKDIR
        FILETYPE = 'BIN'
      TABLES
        DATA_TAB = MIME[]. 

выполняется, однако файл оказывается пустым, несмотря на то, что табличка mime[] не пуста. Добавил параметр bin_filesize - заработало. Обязательно ли его нужно использовать, Ваш пример без него был рабочим? Если использование обязательно, каким образом можно подсчитать размер файла, хранящегося в веб-репозитории?

РМщик

да, мой пример рабочий, проблем никогда не было (версия 4.7) ...
может Вам попробовать функцию WS_DOWNLOAD ?

vahtang

Для сохранения на локальный компьютер наверное лучше использовать ФМ DOWNLOAD_WEB_OBJECT

Code:

  DATA:
    www TYPE wwwdatatab,
    local_file TYPE localfile,
    rc type i.

  www-relid = 'MI'.
  www-objid = 'ZUZUZU'.  " <- ИМЯ ОБЪЕКТА В SMW0
  local_file = 'c:\zuzuzuzuzu.xls'.

  CALL FUNCTION 'DOWNLOAD_WEB_OBJECT'
    EXPORTING
      key         = www
      destination = local_file
    IMPORTING
      rc          = rc.

sy-uname

vahtang написал(а):

Для сохранения на локальный компьютер наверное лучше использовать ФМ DOWNLOAD_WEB_OBJECT

С чего это вдруг лучше чем официально рекомендованные gui_download/ws_download?

vovochka

Цитата:

С чего это вдруг лучше чем официально рекомендованные gui_download/ws_download?

хм.. WS_DOWNLOAD официально НЕ рекомендован.
SAP настоятельно советует пользоваться классом CL_GUI_FRONTEND_SERVICES.

vga

если в эти ФМ и класс посмотреть, то внутри они используют один и тот же ФМ 'ITS_DOWNLOAD'
и разница только во входных параметрах. GUI работает с большим количеством входных типов данных, ИМХО. И усе.

влад

РМщик написал(а):

да, мой пример рабочий, проблем никогда не было (версия 4.7) ...
может Вам попробовать функцию WS_DOWNLOAD ?

У меня 4.6С, без bin_filesize размер получаемого файла равен 0. По совету vahtang'а воспользовался предложенным ФМ - теперь все ОК. Спасибо за поддержку

Правила форума

Загрузить файл в базу

Кто сейчас на конференции