function sdok_mc_conns_get.
*"----------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(CCS) LIKE  SDOKMCCS-CC_SPACE
*"  TABLES
*"      CONNECTIONS STRUCTURE  SDOKMCON OPTIONAL
*"      ENTITIES STRUCTURE  SDOKMENT OPTIONAL
*"  EXCEPTIONS
*"      BAD_CC_SPACE
*"----------------------------------------------------------------------


  types: connections_tab_t type standard table of sdokmcon
                                            with non-unique default key,
         entities_tab_t type standard table of sdokment
                                            with non-unique default key,
         begin of conns_cache_t,
          ccs         type sdok_ent,
          connections type connections_tab_t,
          entities    type entities_tab_t,
         end of conns_cache_t.

  statics: ls_conns_cache type table of conns_cache_t,
           ls_guid type guid_32,
           ls_last_sync type timestamp,
           ls_x_dirty type xfeld.

  data: l_connections type table of sdokmcon,
        l_entities type table of sdokment,
        l_conns_cache_entry type conns_cache_t,
        l_ccs type sdokmccs.

  field-symbols: <l_fs_conns_cache_entry> type conns_cache_t.

  if ccs is initial.
    raise bad_cc_space.
  endif.

* synchronize cache
  call function 'SDOK_MC_SYNC_CACHE'
       exporting
            cache_id     = c_shbuf_conns_get
       changing
            cache_table1 = ls_conns_cache
            x_dirty      = ls_x_dirty
            guid         = ls_guid
            last_sync    = ls_last_sync.

* check if data is already in cache
  read table ls_conns_cache assigning <l_fs_conns_cache_entry>
                             with key ccs = ccs.
  if sy-subrc = 0.
    if connections is requested.
      connections[] = <l_fs_conns_cache_entry>-connections[].
    endif.

    if entities is requested.
      entities[] = <l_fs_conns_cache_entry>-entities[].
    endif.
  else.
*   read from model layer
    sdokm_make_cspc l_ccs ccs sdokm_ev_active.
    call function 'SDOK_M_CONNS_GET'
         exporting
              ccs          = l_ccs
         tables
              connections  = l_connections
              entities     = l_entities
         exceptions
              bad_cc_space = 1.

    if sy-subrc <> 0.
      raise bad_cc_space.
    endif.

*   insert into cache
    l_conns_cache_entry-ccs = ccs.
    insert lines of l_connections
                  into table l_conns_cache_entry-connections.
    insert lines of l_entities
                  into table l_conns_cache_entry-entities.
    insert l_conns_cache_entry into table ls_conns_cache.

    ls_x_dirty = 'X'.
    call function 'SDOK_MC_SYNC_CACHE'
         exporting
              cache_id     = c_shbuf_conns_get
              x_force_sync = 'X'
         changing
              cache_table1 = ls_conns_cache
              x_dirty      = ls_x_dirty
              guid         = ls_guid
              last_sync    = ls_last_sync.

*   transfer requested data
    if connections is requested.
      connections[] = l_connections[].
    endif.

    if entities is requested.
      entities[] = l_entities[].
    endif.

  endif.
endfunction.