Скрыть группу полей ввода

Igor Garanichev

Доброе время суток.
Есть проблемка

SELECTION-SCREEN BEGIN OF BLOCK block1 WITH FRAME TITLE text-002.
PARAMETERS mvz LIKE csks-kostl OBLIGATORY VALUE CHECK.
SELECTION-SCREEN END OF BLOCK block1.

SELECTION-SCREEN BEGIN OF BLOCK block3 WITH FRAME TITLE text-004.
PARAMETERS: r1 RADIOBUTTON GROUP rad1 DEFAULT 'X',
r2 RADIOBUTTON GROUP rad1.
SELECTION-SCREEN END OF BLOCK block3.

Объявил два блока.
Подскажите как мне по выбору радиобаттона, делать первый блок с полем скрытым, защищенным от ввода данных?

nicky555

см. Help на:
1) parameters ... modif id ...
2) at selection-screen output
3) parameters ... radiobutton ... user-command ...
4) loop at screen.

flipper

или вот похожий пример из help-а

Code:

PARAMETERS show_all AS CHECKBOX USER-COMMAND flag. 

SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME. 
PARAMETERS: p1(10) TYPE c, 
            p2(10) TYPE c, 
            p3(10) TYPE c. 
SELECTION-SCREEN END OF BLOCK b1. 

SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME. 
PARAMETERS: p4(10) TYPE c MODIF ID bl2, 
            p5(10) TYPE c MODIF ID bl2, 
            p6(10) TYPE c MODIF ID bl2. 
SELECTION-SCREEN END OF BLOCK b2. 

AT SELECTION-SCREEN OUTPUT. 
  LOOP AT SCREEN. 
    IF show_all <> 'X' AND 
       screen-group1 = 'BL2'. 
       screen-active = '0'. 
    ENDIF. 
    MODIFY SCREEN. 
  ENDLOOP. 

РМщик

Code:

REPORT Z1.

SELECTION-SCREEN BEGIN OF BLOCK BLOCK1 WITH FRAME TITLE TEXT-002.
PARAMETERS MVZ LIKE CSKS-KOSTL OBLIGATORY VALUE CHECK MODIF ID B1.
SELECTION-SCREEN END OF BLOCK BLOCK1.

SELECTION-SCREEN BEGIN OF BLOCK BLOCK3 WITH FRAME TITLE TEXT-004.
PARAMETERS: R1 RADIOBUTTON GROUP RAD1 DEFAULT 'X'
           MODIF ID B2  USER-COMMAND RRR,
            R2 RADIOBUTTON GROUP RAD1 MODIF ID B2.
SELECTION-SCREEN END OF BLOCK BLOCK3.



AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF SCREEN-GROUP1 = 'B1'.
      IF R2 = 'X'.
        SCREEN-INVISIBLE = 1.
        SCREEN-OUTPUT  = 0.
        SCREEN-INPUT  = 0.
      ELSE.
        SCREEN-INVISIBLE = SPACE.
        SCREEN-OUTPUT  = 1.
        SCREEN-INPUT  = 1.
      ENDIF.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.


START-OF-SELECTION.

Удав

РМщик написал(а):

Code:

REPORT Z1.
....
AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF SCREEN-GROUP1 = 'B1'.
      IF R2 = 'X'.
        SCREEN-INVISIBLE = 1.
        SCREEN-OUTPUT  = 0.
        SCREEN-INPUT  = 0.
      ELSE.
        SCREEN-INVISIBLE = SPACE.

Этого не нужно. SCREEN-INPUT = 1 "портит" SELECT-OPTIONS

Code:

        SCREEN-OUTPUT  = 1.
        SCREEN-INPUT  = 1.

РМщик написал(а):

Code:

      ENDIF.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.


START-OF-SELECTION.

Coldblooded

Только пока хотя бы один обязательный параметр на экране будет незаполненым, данный способ работать не будет.

Правила форума

Скрыть группу полей ввода

Кто сейчас на конференции